Salesforce測試失敗，但在系統上工作

Question

我已經編寫了Saleforce觸發器的測試。每當'Account_Status__c'更改時，觸發器將Account_Status_Change_Date__c值更改爲當前日期。

我已通過Web GUI實際更改了帳戶狀態的值，並且帳戶狀態更改日期確實設置爲當前日期。但是，我的測試代碼似乎沒有啓動這個觸發器。我想知道是否有人知道這個原因。

我的代碼如下：

@isTest 
public class testTgrCreditChangedStatus { 

    public static testMethod void testAccountStatusChangeDateChanged() { 

     // Create an original date 
     Date previousDate = Date.newinstance(1960, 2, 17); 

     //Create an Account 
     Account acc = new Account(name='Test Account 1'); 
     acc.AccountNumber = '123'; 
     acc.Customer_URN_Number__c = '123'; 
     acc.Account_Status_Change_Date__c = previousDate; 
     acc.Account_Status__c = 'Good'; 
     insert acc; 

     // Update the Credit Status to a 'Bad Credit' value e.g. Legal 
     acc.Account_Status__c = 'Overdue'; 
     update acc; 

     // The trigger should have updated the change date to the current date 
     System.assertEquals(Date.today(), acc.Account_Status_Change_Date__c); 
    } 
} 

trigger tgrCreditStatusChanged on Account (before update) { 

    for(Account acc : trigger.new) { 
     String currentStatus = acc.Account_Status__c; 
     String oldStatus = Trigger.oldMap.get(acc.id).Account_Status__c; 

     // If the Account Status has changed... 
     if(currentStatus != oldStatus) { 
      acc.Account_Status_Change_Date__c = Date.today(); 
     } 
    } 
} 

Answer 1

你並不需要一個觸發器來做到這一點。這可以通過賬戶上的簡單工作流規則來完成。但是，測試代碼的問題在於，您需要在更新後查詢帳戶以獲取帳戶字段中的更新值。

public static testMethod void testAccountStatusChangeDateChanged() { 

    ... 
    insert acc; 

    Test.StartTest(); 
    // Update the Credit Status to a 'Bad Credit' value e.g. Legal 
    acc.Account_Status__c = 'Overdue'; 
    update acc; 
    Test.StopTest(); 

    acc = [select Account_status_change_date__c from account where id = :acc.id]; 
    // The trigger should have updated the change date to the current date 
    System.assertEquals(Date.today(), acc.Account_Status_Change_Date__c); 
}