批處理語句不起作用

Question

在我的批處理文件中，我有一個if語句，這是行爲不端。我錯過了哪些是造成這種情況的原因？

if "%moveType%"=="file" (
echo Arcval File Move 1>>"%logfile%" 2>&1 

if not exist %arcval_folder% (
    mkdir %arcval_folder% 
    echo Directory: %arcval_folder% created. 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 
) 

echo xcopy "%src_dir%" "%tgt_dir%" 1>>"%logfile%" 2>&1 
echo F|xcopy "%src_dir%" "%tgt_dir%" 1>>"%logfile%" 2>&1 

if ERRORLEVEL 1 (
    echo Failure: File not found, Arcval File not promoted. 1>>"%logfile%" 2>&1 
    echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalFailure-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Failure! File not found, Arcval File not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalFailure-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Failure! File not found, Arcval File not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 

    echo Failure email sent, exiting program. 

) else (
    echo Success: Arcval File was successfully promoted. 1>>"%logfile%" 2>&1 
    echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Arcval File was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Arcval File was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 

    echo Success email sent, exiting program. 
) 

goto end 

) 

if "%moveType%"=="directory" (
echo Polysystems Directory Move 1>>"%logfile%" 2>&1 

if not exist %tgt_dir% (
    mkdir %tgt_dir% 
    echo Directory: %tgt_dir% created. 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 
) else (
    echo ERROR: Polysystems Target directory already exists, Source was not promoted. 1>>"%logfile%" 2>&1 
    echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsErr-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "ERROR! Polysystems Target directory already exists, Source was not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 

    "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsErr-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "ERROR! Polysystems Target directory already exists, Source was not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 
    echo Failure email sent, exiting program. 1>>"%logfile%" 2>&1 
    exit 
) 

echo xcopy %src_dir% %tgt_dir% /Y /Z /C /F /E 1>>"%logfile%" 2>&1 
echo F|xcopy %src_dir% %tgt_dir% /Y /Z /C /F /E 1>>"%logfile%" 2>&1 

echo Success: Polysystems Directory was successfully promoted. 1>>"%logfile%" 2>&1 
echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Polysystems Directory was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
ECHO. 1>>"%logfile%" 2>&1 

"\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Polysystems Directory was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
ECHO. 1>>"%logfile%" 2>&1 
echo Success email sent, exiting program. 1>>"%logfile%" 2>&1 

goto end 
) 

這是它是如何表現：當移動類型==文件，它貫穿，如果聲明就好了，但是，當移動式==目錄，腳本死了，沒有做任何事情。

當if語句切換（目錄第一，第二的文件）目錄中的作品和文件不

Answer 1

我只能想出一個可能會導致您描述的行爲的場景。我懷疑，如果moveType =目錄，則不能定義arcval_folder。相反，如果moveType = file，則不能定義tgt_dir。

你的代碼在這種情況下會失敗的原因是因爲複雜的IF語句被一次全部解析，包括所有相關的代碼塊。即使IF語句的計算結果爲FALSE，整個複雜語句也必須具有有效的語法。如果IF語句的某些部分沒有正確解析，那麼批處理腳本將以語法錯誤結束。

所以，如果moveType =目錄和arcval_folder是不確定的，那麼第一個IF塊如下所示後變量擴展：

if "file" == "file" (
    echo .... 
    if not exist (
    etc. 
) 
    etc. 
    goto end 
) 

內IF NOT EXIST聲明無效，而整個腳本失敗。

如果moveType = file且tgt_dir未定義，那麼第二個IF塊將是無效的，但第一個IF塊中的GOTO END繞過問題。如果您顛倒IF塊的順序，則在這種情況下只有問題。

最簡單的解決方案是將IF NOT EXIST文件夾放在引號中。 Foxidrive也是正確的，你可能應該包括一個尾隨\，以確保你只是在尋找文件夾。

if not exist "%arcval_folder%\" (... 

if not exist "%tgt_dir%\" (... 

Answer 2

使用雙引號字符，丟棄所有多餘的空白：

if "%moveType%"=="directory" (

Answer 3

從這裏%tgt_dir%和其他變量不用雙引號，空格/ &字符會打破它。

if not exist %tgt_dir% (

，並在本次測試還需要一個尾部的反斜槓否則就太匹配文件名。

if not exist "%tgt_dir%\" (