如何確定文件是否被其他進程使用？

Question

我想將數據保存到Excel單元格中，但是如果Excel文件是由其他進程打開的，那麼它會失敗，所以如何確定文件在被其他進程使用之前是否被其他進程使用？

感謝，

Answer 1

MS對如何檢查是否可以訪問文件或者不是你嘗試使用他們編寫的名爲FileLocked函數打開它之前一個很好的例子。

Sub YourMacro() 
    Dim strFileName As String 
    ' Full path and name of file. 
    strFileName = "C:\test.doc" 
    ' Call function to test file lock. 
    If Not FileLocked(strFileName) Then 
     ' If the function returns False, open the document. 
     Documents.Open strFileName 
    End If 
End Sub 

這裏是功能（如寫MS）：從微軟

Function FileLocked(strFileName As String) As Boolean 
    On Error Resume Next 
    ' If the file is already opened by another process, 
    ' and the specified type of access is not allowed, 
    ' the Open operation fails and an error occurs. 
    Open strFileName For Binary Access Read Write Lock Read Write As #1 
    Close #1 
    ' If an error occurs, the document is currently open. 
    If Err.Number <> 0 Then 
     ' Display the error number and description. 
     MsgBox "Error #" & Str(Err.Number) & " - " & Err.Description 
     FileLocked = True 
     Err.Clear 
    End If 
End Function 

參考：http://support.microsoft.com/kb/209189

Answer 2

Followingon從Issun的答案，如果你發現，微軟的FileLocked功能不工作（例如，我發現它會錯誤地聲稱當前正在錄製的WTV文件沒有被鎖定），那麼你可以使用這種方法，而不是更加殘忍：

Function FileLocked(sFilename) As Boolean 
    Dim oFile, sNewFile, iCount 
    If fso.FileExists(sFilename) = False Then 
     FileLocked = False 
     Exit Function 
    End If 
    ' Pick a random, unused, temp name 
    iCount = 0 
    Do 
     sNewFile = sFilename & ".tmp" & iCount 
     iCount = iCount + 1 
    Loop Until fso.FileExists(sNewFile) = False 
    ' Try to rename it to that. If it fails, then it is in use 
    On Error Resume Next 
    fso.MoveFile sFilename, sNewFile 
    If Err.Number = 0 Then 
     ' It moved okay, so rename it back 
     fso.MoveFile sNewFile, sFilename 
     FileLocked = False 
    Else 
     FileLocked = True 
    End If 
    On Error Goto 0  
End Function