總和未鏈接

嗨，總和未鏈接

新建XSLT和已調試該代碼了一會兒

當前變量總是返回0

我需要通過每個（行）找到所有（X）與（d）相同的值的總和

V和W是相關的，不知道如何「連接」他們

實施例：

Row (AAA123)[SomeDesc1] = 1.00 + 

Row (BBB456)[SomeDesc1] = 3.00 

SumOfSomeDesc1 = 4.00

XSLT 1.0只

XML：

<Root> 
    <Row> 
    <ID>AAA123</ID> 
    <V> 
     <X>1.00</X> 
    </V> 
    <V> 
     <X>2.00</X> 
    </V> 
    <MultipleFieldsInBetween /> 
    <W> 
     <D>SomeDesc1</D> 
    </W> 
    <W> 
     <D>SomeDesc2</D> 
    </W> 
    </Row> 
    <Row> 
    <ID>BBB456</ID> 
    <V> 
     <X>3.00</X> 
    </V> 
    <V> 
     <X>4.00</X> 
    </V> 
    <MultipleFieldsInBetween /> 
    <W> 
     <D>SomeDesc1</D> 
    </W> 
    <W> 
     <D>SomeDesc2</D> 
    </W> 
    </Row> 
</Root>

XSLT薩姆（當前）：

<xsl:variable name="SumOfX" select="sum(//Row[ID/text()=$ID]/V[D/text() 
=$Description])" />

來源

2017-09-27 Neal_RSA

怎麼樣'V'和'W'與該位置相關的是'Row'的第一個'V'子屬於第一個'W'子嗎？ –

@MartinHonnen位置是，V [x] W [x]，真的不知道爲什麼它不僅僅是一個元素，而是我必須使用它作爲 –

我會解決它作爲一個分組的問題，首先確定獨特的說明，然後由描述找到秒和最終總結在相同位置的元素：

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"> 

    <xsl:key name="desc-group" match="Row/W/D" use="."/> 

    <xsl:variable name="desc-groups" select="//Row/W/D[generate-id() = generate-id(key('desc-group', .)[1])]"/> 

    <xsl:key name="row-group" match="Row" use="W/D"/> 

    <xsl:template match="/Root"> 
     <html> 
      <body> 
       <table> 
        <thead> 
         <tr> 
          <th>Description</th> 
          <th>Sum</th> 
         </tr> 
        </thead> 
        <tbody> 
         <xsl:apply-templates select="$desc-groups"/> 
        </tbody> 
       </table> 
      </body> 
     </html> 
    </xsl:template> 

    <xsl:template match="Row/W/D"> 
     <tr> 
      <td> 
       <xsl:value-of select="."/> 
      </td> 
      <td> 
       <xsl:variable name="pos" select="count(.. | ../preceding-sibling::W)"/> 
       <xsl:value-of select="sum(key('row-group', .)/V[position() = $pos]/X)"/> 
      </td> 
     </tr> 
    </xsl:template> 
</xsl:stylesheet>

結果是

<html> 
    <body> 
     <table> 
     <thead> 
      <tr> 
       <th>Description</th> 
       <th>Sum</th> 
      </tr> 
     </thead> 
     <tbody> 
      <tr> 
       <td>SomeDesc1</td> 
       <td>4</td> 
      </tr> 
      <tr> 
       <td>SomeDesc2</td> 
       <td>6</td> 
      </tr> 
     </tbody> 
     </table> 
    </body> 
</html>

來源

2017-09-27 09:24:08

我同意馬丁。分組似乎是對所述問題的合理解決方案。 – FarligOpptreden

回答

相關問題