單元測試GORM調用與閉合

Question

我有一個Grails的服務，做了where這樣的查詢：

List<Car> search(Long makeId = null) { 
    Car.where { 
     join("make") 
     if(makeId) { 
      make.id == makeId 
     } 
    }.findAll() 
} 

我試圖單元測試與斯波克這樣的：

def setup() { 
    GroovyMock(Car, global: true) 
} 

void "test search"() { 
    when: 
     service.search() 
    then: 
     1 * Car.where {} 
} 

但是，我似乎無法找到一種方法來測試閉包的內容。

我可以得到測試通過驗證1 * Car.where(_)通過，但我怎麼能在封閉的內容的斷言，即認爲join被稱爲並在需要時make.id約束只規定？

Answer 1

您可以將閉包的委託設置爲DetachedCriteria的模擬來對其進行斷言。 DetachedCriteria是gorm構建查詢的主要類。

實施例：

given: 'Mocking DetachedCriteria' 
DetachedCriteria detachedCriteriaMock = Mock(DetachedCriteria) 
and: 'Just to avoid nullPointerException when findAll() call happens on service' 
1 * detachedCriteriaMock.iterator() >> [].listIterator() 
when: 
service.search(1L) 
then: 
// Capture the argument 
1 * Car.where(_) >> { args -> 
    args[0].delegate = detachedCriteriaMock 
    args[0].call() 

    return detachedCriteriaMock 
} 

// Join is a method on detached criteria 
1 * detachedCriteriaMock.join('make') 
// Make is an association, so detachedCriteria uses the methodMissing to find the property. 
// In this case, we call the closure setting the delegate to the mock 
1 * detachedCriteriaMock.methodMissing('make', _) >> { args -> 
    // args[1] is the list of arguments. 
    // args[1][0] is the closure itself passed to detachedCriteria 
    args[1][0].delegate = detachedCriteriaMock 
    args[1][0].call() 
} 
// If id is passed, it must compare (eq method) with value 1 
1 * detachedCriteriaMock.eq('id', 1L)