RegExp55修改大量的Excel公式

Question

我在Excel電子表格如下：

+---+----+-----------------------------+----------------------------+ 
| | A |    B    |    C    | 
+---+----+-----------------------------+----------------------------+ 
| 1 | |        |       | 
| 2 | 12 | =IF(ISERROR(A2/0),"",A2/0) | =IF(ISERROR(A2*4),"",A2*4) | 
+---+----+-----------------------------+----------------------------+ 

，我想爲下面

+---+----+--------+-------+ 
| | A | B | C | 
+---+----+--------+-------+ 
| 1 | |  |  | 
| 2 | 12 | =A2/0 | =A2*4 | 
+---+----+--------+-------+ 

所以我寫了這個VBA代碼：

Sub DeleteIfError() 


    Dim c As Integer 
    Dim r As Integer 
    Dim regex As Object, str As String 
    Set regex = CreateObject("VBScript.RegExp") 

    With regex 
    .Pattern = "=IF(ISERROR\([A-Za-z0-9]+\)" 
    .Global = False 'Only First 
    End With 

For c = 1 To 3 
    For r = 1 To 2 
     If Cells(r, c).HasFormula Then 

      Set matches = regex.Execute(str) 
       For Each Match In matches 
        Cells(r, c) = Match.Value 
       Next Match 
     End If 

    Next r 
Next c 

End Sub 

但它給我一個運行時錯誤5020. 我認爲問題是在模式，但我重新盟友無法理解如何解決它。任何人都可以幫助我嗎？

Answer 1

您可以使用以下修正：

1）正則表達式必須^=IF\(ISERROR\(([^)]+)\).*和替換模式應設爲=$1（見the regex demo）
2）您需要使用.Replace而非.Execute更換式
3）您傳遞的字符串必須是公式，更新的字符串應分配給單元格公式。

正則表達式匹配：

• ^ - 串的開始
• =IF\(ISERROR\( - 一個文字字符序列=IF(ISERROR(
• ([^)]+) - 捕獲組1（稱爲與$1以後）匹配比其他1+字符)
• \) - 字面)
• .* - 排隊到結束的其餘

代碼：

Sub DeleteIfError() 
    Dim c As Integer 
    Dim r As Integer 
    Dim regex As Object, str As String 
    Set regex = CreateObject("VBScript.RegExp") 

    With regex 
    .pattern = "^=IF\(ISERROR\(([^)]+)\).*" 
    .Global = False 'Only First 
    End With 

For c = 1 To 3 
    For r = 1 To 2 
     If Cells(r, c).HasFormula Then 
      Cells(r, c).Formula = regex.Replace(Cells(r, c).Formula, "=$1") 
     End If 

    Next r 
Next c 

End Sub