如何從字符串VBA中刪除單個空格（不刪除連續空格）

Question

我在vba中編寫代碼以取出一個字符串並刪除所有出現的單個空格，同時保留連續的空格。

這就是我現在所擁有的，但它只是刪除所有空間並用短劃線替換它們。

感謝您的任何幫助或指導！

Sub Main 
    'Nothing happens when the code executes the following string 
    CombineText("Job   Hours  Pay Labor %") 

    'When the following executes it should look like this 
    'Major-Group-Total  382  2,085.25 
    CombineText("Major Group Total  382  2,085.25") 
End Sub 

Sub CombineText(searchString As String) 
    a = Len(searchString) 

    For n = 1 To a  
     If Mid(searchString, n, 1) = Chr(32) Then 
      searchString = Application.Substitute(searchString, Mid(searchString, n, 1), "-") 
     End If 
    Next n 
End Sub 

Answer 1

Function CombineText(sSearch As String) As String 

    Dim i As Long 
    Dim sReturn As String 

    sReturn = sSearch 

    For i = 2 To Len(sReturn) - 1 
     If Mid$(sSearch, i, 1) = Space(1) And Mid$(sSearch, i - 1, 1) <> Space(1) And Mid$(sSearch, i + 1, 1) <> Space(1) Then 
      Mid$(sReturn, i, 1) = "-" 
     End If 
    Next i 

    CombineText = sReturn 

End Function 

?combinetext("Major Group Total  382  2,085.25") 
Major-Group-Total  382  2,085.25 
?combinetext("Job   Hours  Pay Labor %") 
Job   Hours  Pay Labor-% 

Answer 2

你也可以使用一個RegExp通過人物爲此在單杆，而不是循環

Function CleanStr(strIn As String) As String 
Dim objRegex As Object 
Set objRegex = CreateObject("vbscript.regexp") 
With objRegex 
.Pattern = "(\S)\s(?=\S)" 
.Global = True 
CleanStr = .Replace(strIn, "$1-") 
End With 
End Function 

Sub Test() 
Debug.Print CleanStr("Job   Hours  Pay Labor %") 
Debug.Print CleanStr("Major Group Total  382  2,085.25") 
End Sub