運行在具有指定名稱

Question

我試圖寫一個粘貼在與他們的價值觀一定的命名工作表中公式的宏，從而使他們出口的工作表的宏。我已經成功地獲得了這個宏來重命名工作表，但是無法像我想的那樣獲取它們的副本/粘貼。

目前我的宏複製，除了一個指定的（「儀表板」）的所有可見的工作表，然後重命名這些，「（2）」與「_VARIABLES」代替。到現在爲止還挺好。然後它應該用新值覆蓋新創建的工作表中的公式。這部分不起作用。

這裏是整個代碼：

Private Sub testestssss() 

Dim ws As Worksheet 

'Copy all visible worksheets except "Dashboard" to the end 

For Each ws In Sheets 

If ws.Name = "Dashboard" Then 
Else 
If ws.Visible Then ws.Copy after:=Worksheets(Worksheets.Count) 
End If 

Next 

'Rename all "wk * (2)" sheets to "wk *_VARIABLES" 

For Each ws In Sheets 
If ws.Name Like "* (2)" Then 
ws.Name = Replace(ws.Name, " (2)", "_VARIABLES") 
End If 
Next 

'Overwrite all "wk *_VARIABLES" formulae with values 

For Each ws In Sheets 
If ws.Name Like "*_VARIABLES" Then 
Columns("A:B").Select 
Selection.Copy 
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
    :=False, Transpose:=False 
End If 
Next 

End Sub 

因此，所有上述工作，直到「覆蓋所有‘周* _VARIABLES’的公式與價值觀」的一部分。這似乎是無效的。

任何幫助將不勝感激！

謝謝。

Answer 1

你不斷選擇活動工作表的列。這應該做你所期望的：

For Each ws In Sheets 
    If ws.Name Like "*_VARIABLES" Then 
     ws.Select 
     Columns("A:B").Select 
     Selection.Copy 
     Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
            :=False, Transpose:=False 
    End If 
Next 

或者，你可以簡單地寫這個（沒有必要選擇，它運行快一點沒有他們）：

For Each ws In Sheets 
    If ws.Name Like "*_VARIABLES" Then 
     ws.Columns("A:B").Copy 
     ws.Columns("A:B").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, _ 
             SkipBlanks:=False, Transpose:=False 
    End If 
Next 

最後保存幾個按鍵：

For Each ws In Sheets 
    If ws.Name Like "*_VARIABLES" Then 
     With ws.Columns("A:B") 
      .Copy 
      .PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, _ 
          SkipBlanks:=False, Transpose:=False 
     End With 
    End If 
Next 

而且不要忘了複製/粘貼節之後添加以下語句：

Application.CutCopyMode = False 

保持乾淨的東西。