如何在斷開foreach循環後重新啓動「do-while」循環？

Question

我的配置腳本中有一小段代碼，想法是配置被加載，然後檢查每個鍵是否已輸入主機名。但是，如果發現某個配置包含相同的主機名，則它將被拒絕並顯示一條警告消息，指出該主機名的配置已存在。

問題是我需要foreach循環檢查散列鍵的存在以重新啓動do-while循環，以便可以嘗試另一個主機名，或者用戶可以將^C排除在腳本之外。

這是摘錄;

my $host; 
do { 
    print "Enter the hostname or IP of the ESXi server: "; 
    chomp($host = <STDIN>); 

    if ($host eq '') { 
     print "You must enter a hostname or IP address!\n"; 
    } elsif ($host ne '') { 

     # We need to catch duplicate configurations for we don't do the same work twice 
     foreach (keys %config) { 
      if ($config{$_}{host} ne $host) { 
       last; 
      } elsif ($config{$_}{host} eq $host) { 
       warn "Configuration for $host already exists!\n"; 
      } 
     } 

     if ($ping_obj->ping($host)) { 
      $config{$config_tag}{host} = $host; 
     } elsif (! $ping_obj->ping($host)) { 
      print RED . "Ping test for \'$host\' failed" . RESET . "\n"; 
     } 

     $ping_obj->close(); 
    } 
} while ($config{$config_tag}{host} eq 'undef'); 

這就是模板哈希的樣子。

my %template = (
    host => 'undef', 
    port => 'undef', 
    login => { 
     user => 'undef', 
     password => 'undef', 
    }, 
    options => { 
     snapshots => "0", 
     compress => "0", 

     # This is expressed as an array 
     exclude => 'undef', 
    }, 
); 

Answer 1

如果在Perl中有一個goto LABEL語句的用法，就是這樣。

do { 
    START:  # could also go right before the "do" 
    ... 
    if (...) { 
     warn "Configuration exists. Start over.\n"; 
     goto START; 
    } 
} while (...); 

Answer 2

我不知道你爲什麼要使用do ... while，當while看起來更自然。

一些注意事項：

• 你並不需要仔細檢查您的if語句。如果例如$host eq ''爲真，那麼$host ne ''必須爲假。每個定義。
• 如果你不打算在循環外部使用$host，我假設你不是 ，因爲你將它存儲在散列中，所以你應該在循環內部放置my $host來限制範圍。

一些提示：

• 您可以使用redo重新啓動循環。
• 您可以使用smart matching來取消for循環。

---

while ($config{$config_tag}{host} eq 'undef') { 
    print "Enter the hostname or IP of the ESXi server: "; 
    chomp(my $host = <STDIN>); 
    if ($host eq '') { 
     print "You must enter a hostname or IP address!\n"; 
     redo; 
    } else { 
     # We need to catch duplicate configurations 
     my @host_list = map { $_->{host} } values %config 
     if ($host ~~ @host_list) { 
      warn "Configuration for $host already exists!\n"; 
      redo; 
     } 
    } 
    if ($ping_obj->ping($host)) { 
     $config{$config_tag}{host} = $host; 
    } else { 
     print RED . "Ping test for \'$host\' failed" . RESET . "\n"; 
    } 
    $ping_obj->close(); 
} 

Answer 3

爲什麼你有3個elsif S其中一個簡單的else會做什麼？
我的意思是，他們只測試相關的if測試的完全相反。

if ($host eq '') { 
    ... 
} elsif ($host ne '') { 
    ... 
} 

if ($config{$_}{host} ne $host) { 
    ... 
} elsif ($config{$_}{host} eq $host) { 
    ... 
} 

if ($ping_obj->ping($host)) { 
    ... 
} elsif (! $ping_obj->ping($host)) { 
    ... 
} 

---

我會用一個正常的while循環，而不是do{...}while(...)循環。

do{ 
    RESTART: 
    if(...){ 
    goto RESTART; 
    } 
}while(...); 

VS

while(...){ 
    if(...){ 
    redo; 
    } 
} 

---

在這個循環中，您只使用%config的鑰匙，找到關聯的值，那麼你爲什麼不使用values %config代替。

foreach (keys %config) { 
    if ($config{$_}{host} ne $host) { 
     last; 
    } elsif ($config{$_}{host} eq $host) { 
     warn "Configuration for $host already exists!\n"; 
    } 
} 

VS

for(values %config){ 
    if($_->{host} ne $host){ 
    ... 
    } else { 
    ... 
    } 
} 

如果您使用5.10.0或更高版本，你可以使用一個smart match (~~)相反，這將使你測試更清楚什麼。

my @hosts = map{ $_->{host} } values %config; 
if($host ~~ @hosts){ 
    ... 
}