爲什麼在F＃模式匹配中某些表達式中的泛型類型與obj相匹配？

Question

我有以下代碼：

type Message<'a> = | Message of 'a 

let handleMessage message = 
    match box message with 
    | :? Message<_> -> printfn "Message" 
    | _ -> printfn "Not message" 

let handleMessageEx message = 
    match box message with 
    | :? Message<int> -> printfn "Message" 
    | _ -> printfn "Not message" 

handleMessage <| Message 1 
handleMessage <| Message (1 :> obj) 
handleMessageEx <| Message 1 

在F＃交互式輸出如下：

Not message 
Message 
Message 

爲什麼第一條語句結果「沒有消息」？即當匹配裝箱值F＃無法檢測到它是通用類型消息< _>並且除非我指定底層類型，否則它將其設置爲對象（因此在（消息1）上失敗匹配）。

Answer 1

只要你看到_作爲類型參數，就把它想象成一個你不關心的新類型參數。如果我們據此調整你的第一個定義：

let handleMessage message = 
    match box message with 
    | :? Message<'_a> -> printfn "Message" 
    | _ -> printfn "Not message" 

那麼編譯器爲我們提供了這個有用的線索：

警告FS0064：此構造導致代碼比由類型註釋所列的那樣普通。類型變量'_a被約束爲類型'obj'。

的問題是，該類型參數必須要給出一些具體的值，但是編譯器上沒有依據挑一個，這樣它默認爲obj，這是不是你想要的。

開箱即用並沒有很好的方法，但您可以創建一個活動模式以簡化體驗：https://stackoverflow.com/a/2140485/82959。

Answer 2

簡而言之，Message<_>並不意味着你期望它是通用的，這意味着編譯器可以自由地推斷出Message的泛型類型參數。在沒有其他限制的情況下，其結果是使其成爲obj。如果你做的功能一般也會發生這種情況 - 泛型類型參數的函數（以及由此延伸，以Message類型檢查）在調用點決定：

let handleMessage<'a> (message: obj) = 
    match message with 
    | :? Message<'a> -> printfn "Message" 
    | _ -> printfn "Not message" 

handleMessage <| Message 1  // Not message -> 'a inferred to be obj 
handleMessage<int> <| Message 1 // Message -> 'a inferred to be int 

你可能想要做的是什麼像這樣：

let handleMessage message = 
    let typ = message.GetType() 
    match typ with 
    | _ when typ.GetGenericTypeDefinition() = typedefof<Message<_>> -> printfn "Message" 
    | _ -> printfn "Not message" 

handleMessage <| Message 1 
handleMessage <| Message (1 :> obj) 

這裏不是做一個類型測試，而是檢查兩者的泛型類型定義。