我可以使用屬性ReDim模塊級別數組嗎？

Question

我想我有一個相當不錯的句柄來處理如何通過Property Get和Let來處理VBA中的模塊級數組。有沒有辦法通過屬性ReDim模塊級別的數組？

在上次過程（DoTest）中的ReDim語句處出現以下代碼錯誤。

Private mstrTestArray() As String 

Private Sub Class_Initialize() 
    ReDim mstrTestArray(0) As String 
End Sub 

Private Property Get TestArray() As String() 
    TestArray = mstrTestArray 
End Property 

Private Property Let TestArray(ByRef strTestArray() As String) 
    mstrTestArray = strTestArray 
End Property 

Private Property Get TestArrayValue(d1 As Long) As String 
    TestArrayValue = mstrTestArray(d1) 
End Property 

Private Property Let TestArrayValue(d1 As Long, strValue As String) 
    mstrTestArray(d1) = strValue 
End Property 

Sub DoTest() 
    Dim intCharCode As Integer 
    For intCharCode = 97 To 122 
     If Not Len(TestArrayValue(UBound(TestArray))) > 0 Then 
      TestArrayValue(UBound(TestArray)) = Chr(intCharCode) 
     Else 
      ReDim Preserve TestArray(UBound(TestArray) + 1) As String 
      TestArrayValue(UBound(TestArray)) = Chr(intCharCode) 
     End If 
    Next intCharCode 
    Debug.Print TestArrayValue(LBound(TestArray)) _ 
    & " through " _ 
    & TestArrayValue(UBound(TestArray)) 
End Sub 

謝謝！

Answer 1

這是一個很好的問題。我會直接在底部回答你的問題，但讓我們從VBA中面向對象編程的簡要背景開始。在大多數面向對象的語言，一個財產往往會看起來像場，但行爲像方法。這是什麼意思？

當你實例化一個類和值設置爲一個屬性，它看起來像這樣：

Sub TestMyClass() 
    Dim mc As MyClass 
    Set mc = new MyClass 
    mc.MyProperty = 1 
End Sub 

在上面的代碼，MyProperty看起來像一個領域，對不對？但是，讓我們來看看它是如何在類中定義：

Private pMyProperty As Integer 

Public Property Get MyProperty() As Integer 
    MyProperty = pMyProperty 
End Property 

Public Property Let MyProperty(lMyProperty As Integer) 
    pMyProperty = lMyProperty 
End Property 

正如你可以在上面的代碼中看到，而pMyProperty是一個整場，公衆Get和Set方法MyProperty其實看起來更像方法。一個屬性「圍繞」一個字段，對於設置對基礎字段的訪問特別有幫助。

在你的例子中，你試圖ReDim一個返回對數組的引用的屬性。我不是100％確定的，但我不認爲你可以在參考的數組上使用ReDim。

我改變了你的代碼來修改實際的私人字段mstrTestArray，它似乎工作正常。那是你可以嘗試的嗎？

Sub DoTest() 
    Dim intCharCode As Integer 
    For intCharCode = 97 To 122 
     If Not Len(TestArrayValue(UBound(TestArray))) > 0 Then 
      TestArrayValue(UBound(TestArray)) = Chr(intCharCode) 
     Else 
      ReDim Preserve mstrTestArray(UBound(mstrTestArray) + 1) As String 
      TestArrayValue(UBound(TestArray)) = Chr(intCharCode) 
     End If 
    Next intCharCode 
    Debug.Print TestArrayValue(LBound(TestArray)) _ 
    & " through " _ 
    & TestArrayValue(UBound(TestArray)) 
End Sub