如何獲取比特定日期早的文件？

Question

我很抱歉，如果這個問題已被問到，但我似乎無法找到我正在尋找什麼。我希望能夠找到XP（使用cmd）比特定日期更早的文件。我想要做一些像30天以前的DIR/FIND文件。

以下不起作用，但希望它會給你一個我想要做的事情的想法。

FOR /f %%f IN ('DIR /b /t -30 I:\FOLDER1\*.pdf') DO move /Y Z:\FOLDER1\%%f "I:\FOLDER2\" 

謝謝！

Answer 1

Julian日期函數從DosTips.com function library

採取先使用XCOPY/L/d獲得已修改內過去30天的文件列表：保存到排除列表中。

然後使用XCOPY/L通過FINDSTR獲取所有文件和管道，從排除列表中排除文件並將結果保存到包含列表。

最後遍歷包括列表和移動這些文件

@echo off 
setlocal 

set src="I:\FOLDER1\*.pdf" 
set dest="I:\FOLDER2" 
set incl="%temp%\includeFiles%random%.txt" 
set excl="%temp%\excludeFiles%random%.txt" 

call :jdate jd 
set /a jd-=30 
call :jdate2date jd yyyy mm dd 
xcopy %src% %dest% /d:%mm%-%dd%-%yyyy% /l | findstr /vxrc:"[0-9]* File(s)" >%excl% 
xcopy %src% %dest% /l | findstr /vxrc:"[0-9]* File(s)" | findstr /vixlg:%excl% >%incl% 
set /a "fail=0, ok=0" 
for /f "usebackq eol=: delims=" %%F in (%incl%) do (
    move /y "%%F" %dest% >nul 2>&1 && (
    echo "%%F" 
    set /a "ok+=1" 
) || (
    >&2 echo ERROR: Unable to move "%%F" 
    set /a "fail+=1" 
) 
) 
echo ---------------------- 
echo Moved %ok% files 
if %fail% gtr 0 echo Failed to move %fail% files 
del %excl% 
del %incl% 
exit /b %fail% 


:jdate2date JD YYYY MM DD -- converts julian days to gregorian date format 
::      -- JD [in] - julian days 
::      -- YYYY [out] - gregorian year, i.e. 2006 
::      -- MM [out] - gregorian month, i.e. 12 for december 
::      -- DD [out] - gregorian day, i.e. 31 
:$reference http://aa.usno.navy.mil/faq/docs/JD_Formula.html 
:$created 20060101 :$changed 20080219 :$categories DateAndTime 
:$source http://www.dostips.com 
SETLOCAL ENABLEDELAYEDEXPANSION 
set /a L= %~1+68569,  N= 4*L/146097, L= L-(146097*N+3)/4, I= 4000*(L+1)/1461001 
set /a L= L-1461*I/4+31, J= 80*L/2447, K= L-2447*J/80,  L= J/11 
set /a J= J+2-12*L,  I= 100*(N-49)+I+L 
set /a YYYY= I, MM=100+J, DD=100+K 
set MM=%MM:~-2% 
set DD=%DD:~-2% 
(ENDLOCAL & REM RETURN VALUES 
    IF "%~2" NEQ "" (SET %~2=%YYYY%) ELSE echo.%YYYY% 
    IF "%~3" NEQ "" (SET %~3=%MM%) ELSE echo.%MM% 
    IF "%~4" NEQ "" (SET %~4=%DD%) ELSE echo.%DD% 
) 
EXIT /b 

:jdate JD DateStr -- converts a date string to julian day number with respect to regional date format 
::    -- JD  [out,opt] - julian days 
::    -- DateStr [in,opt] - date string, e.g. "03/31/2006" or "Fri 03/31/2006" or "31.3.2006" 
:$reference http://groups.google.com/group/alt.msdos.batch.nt/browse_frm/thread/a0c34d593e782e94/50ed3430b6446af8#50ed3430b6446af8 
:$created 20060101 :$changed 20090328 :$categories DateAndTime 
:$source http://www.dostips.com 
SETLOCAL 
set DateStr=%~2&if "%~2"=="" set DateStr=%date% 
for /f "skip=1 tokens=2-4 delims=(-)" %%a in ('"echo.|date"') do (
    for /f "tokens=1-3 delims=/.- " %%A in ("%DateStr:* =%") do (
     set %%a=%%A&set %%b=%%B&set %%c=%%C)) 
set /a "yy=10000%yy% %%10000,mm=100%mm% %% 100,dd=100%dd% %% 100" 
if %yy% LSS 100 set /a yy+=2000 &rem Adds 2000 to two digit years 
set /a JD=dd-32075+1461*(yy+4800+(mm-14)/12)/4+367*(mm-2-(mm-14)/12*12)/12-3*((yy+4900+(mm-14)/12)/100)/4 
ENDLOCAL & IF "%~1" NEQ "" (SET %~1=%JD%) ELSE (echo.%JD%) 
EXIT /b 

我沒有使用XCOPY /排除選項，因爲它把這些文件具有隱含的通配符。因此，如果您指定*而不是* .pdf，那麼名爲TEST的排除文件也會導致名爲TEST1，TEST.TXT和TEST.EXE的文件也被排除。

在使用多個文字搜索字符串進行搜索時，需要使用FINDSTR/I選項來彌補FINDSTR錯誤。應該不需要/ I選項，但使用多個文字搜索字符串執行區分大小寫的搜索可能會導致錯誤的結果。

Answer 2

使用forfiles：

forfiles /p "i:\folder1" /m *.pdf /d -30 /c "move /y z:\folder1\@file i:\folder2" 

Answer 3

查看答案batch file to delete files older than a specified date一種方式與XCOPY做到這一點。

有了xcopy，你需要指定完整的日期（你不能說「30天前」），但你可以通過其他命令來計算。