如何在VBA中填充單元格中的顏色？

Question

我想爲當前表格中具有「＃N/A」值的單元格着色。爲了做到這一點我使用下面的宏：

Sub ColorCells() 

Dim Data As Range 
Dim cell As Range 
Set currentsheet = ActiveWorkbook.Sheets("Comparison") 
Set Data = currentsheet.Range("A2:AW1048576") 

For Each cell In Data 
If cell.Value = "#N/A" Then 
    cell.Interior.ColorIndex = 3 
End If 
Next 

End Sub 

但行If cell.Value = "#N/A" Then給出了一個錯誤：類型不匹配。也許有人可以幫助理解錯誤在哪裏？由於

Answer 1

非VBA colution：

使用CF規則與公式：=ISNA(A1)（以higlight細胞所有錯誤 - 不僅#N/A，使用=ISERROR(A1)）

VBA解決方案：

您的代碼通過50 mln個單元循環。爲了減少細胞數量，我用.SpecialCells(xlCellTypeFormulas, 16)和.SpecialCells(xlCellTypeConstants, 16)與錯誤只返回細胞（注意，我使用If cell.Text = "#N/A" Then）

Sub ColorCells() 
    Dim Data As Range, Data2 As Range, cell As Range 
    Dim currentsheet As Worksheet 

    Set currentsheet = ActiveWorkbook.Sheets("Comparison") 

    With currentsheet.Range("A2:AW" & Rows.Count) 
     .Interior.Color = xlNone 
     On Error Resume Next 
     'select only cells with errors 
     Set Data = .SpecialCells(xlCellTypeFormulas, 16) 
     Set Data2 = .SpecialCells(xlCellTypeConstants, 16) 
     On Error GoTo 0 
    End With 

    If Not Data2 Is Nothing Then 
     If Not Data Is Nothing Then 
      Set Data = Union(Data, Data2) 
     Else 
      Set Data = Data2 
     End If 
    End If 

    If Not Data Is Nothing Then 
     For Each cell In Data 
      If cell.Text = "#N/A" Then 
       cell.Interior.ColorIndex = 4 
      End If 
     Next 
    End If 
End Sub 

注意，突出細胞WITN任何錯誤（不僅"#N/A"），取代下面的代碼

If Not Data Is Nothing Then 
    For Each cell In Data 
     If cell.Text = "#N/A" Then 
      cell.Interior.ColorIndex = 3 
     End If 
    Next 
End If 

與

If Not Data Is Nothing Then Data.Interior.ColorIndex = 3 

UPD：（如何通過VBA添加CF規則）

Sub test() 
    With ActiveWorkbook.Sheets("Comparison").Range("A2:AW" & Rows.Count).FormatConditions 
     .Delete 
     .Add Type:=xlExpression, Formula1:="=ISNA(A1)" 
     .Item(1).Interior.ColorIndex = 3 
    End With 
End Sub 

Answer 2

1. 使用條件格式，而不是VBA中高亮顯示錯誤。

2. 使用VBA循環就像您發佈將需要很長的時間來處理

3. 聲明If cell.Value = "#N/A" Then不會有任何效果的一個。如果你堅持使用VBA突出顯示錯誤，那就試試這個。

   子ColorCells（）

   Dim Data As Range 
   Dim cell As Range 
   Set currentsheet = ActiveWorkbook.Sheets("Comparison") 
   Set Data = currentsheet.Range("A2:AW1048576") 
   
   For Each cell In Data 
   
   If IsError(cell.Value) Then 
       cell.Interior.ColorIndex = 3 
   End If 
   Next 
   
   End Sub 
   

4. 是漫長的等待準備，因爲該過程循環〜51萬個細胞

5. 有更有效的方式來實現你想要做什麼。如果您改變了主意，請更新您的問題。

Answer 3

1. 選擇通過左上角的所有單元格
2. 選擇[首頁] >> [條件格式] >> [新規則]
3. 選擇[包含格式只有細胞]
4. 在[格式只能用細胞：]，選擇「錯誤」
5. 選擇在適當的格式[格式..]按鈕

Answer 4

您需要使用cell.Text =「＃N/A」而不是cell.Value =「＃N/A」。單元格中的錯誤實際上只是存儲在單元格中的文本。