vba - 循環和重命名文件和文件夾

Question

我想重命名一個文件夾如何有很多子文件夾和主文件夾內的文件 重命名是基於許多值和它的需要是動態的（我正在更改電影&字幕名稱）

我的問題是 - 當文件夾名稱回答名稱的值更改宏無法找到一個路徑來繼續循環（如果文件夾不回答價值，那麼宏工作正常）

這裏我到目前爲止：

Sub moviestest() 
    Call VideoLibrary("C:\movies") 
End Sub 

Private Sub VideoLibrary(path As String) 
    Dim fso As New Scripting.FileSystemObject 
    Dim fld As folder, f As folder, fl As File 

    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set fld = fso.GetFolder(path) 

    For Each Q In Range("Qname") 
     For Each fl In fld.Files 

      myMovie = fl.Name 
      extension = InStrRev(myMovie, ".") 
      myNewMovie = _ 
       Replace(_ 
        Replace(_ 
         Replace(_ 
          Replace(_ 
           Left(myMovie, extension - 1), _ 
          ".", " "), _ 
         "-", " "), _ 
        "_", " "), _ 
       Q, "") & _ 
       Mid(myMovie, extension) 
      fso.MoveFile myMovie, myNewMovie 
     Next 
    Next 


    For Each f In fld.SubFolders 
      Call VideoLibrary(f.path) 
    Next 
End Sub 

文件名正在尋找這樣的事情：

• The.something.2013.1080p.BluRay.x264.YIFY.mkv The.something.2013.1080p.BluRay.x264.YIFY.sub Zero.something。 2016.1080p.BluRay.x264- [YTS.AG] .AVI（以及更多 名稱）

QName的範圍是somethig這樣的： （在Excel命名範圍）

bdrip 
x264 
veto 
heb 
BRRip 
XviD 
AC3 
EVO 
blaa 
1080p 
BluRay 
YIFY 

這是我第一次在這個論壇上發問。我希望我儘可能地明確我的問題 任何幫助將不勝感激

Answer 1

最好的辦法是使一個函數，將返回新的名稱。這也將使代碼更易於閱讀，修改和調試。

Sub moviestest() 
    Call VideoLibrary("C:\movies") 
End Sub 

Private Sub VideoLibrary(path As String) 
    Dim fso As New Scripting.FileSystemObject 
    Dim fld As folder, f As folder, fl As File 

    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set fld = fso.GetFolder(path) 

    For Each fl In fld.Files 
     fso.MoveFile fl.path, fl.ParentFolder & "\" & getNewMoiveName(fl.Name) 
    Next 

    For Each f In fld.SubFolders 
     Call VideoLibrary(f.path) 
    Next 
End Sub 

Function getNewMoiveName(myMovie As String) As String 
    Dim Q 
    Dim loc As Long 
    Dim extension As String 
    loc = InStrRev(myMovie, ".") 
    extension = Right(myMovie, Len(myMovie) - loc) 
    myMovie = Left(myMovie, loc - 1) 
    myMovie = Replace(myMovie, ".", " ") 
    myMovie = Replace(myMovie, "-", " ") 

    For Each Q In Range("Qname") 
     myMovie = Replace(myMovie, Q, "") 
    Next 

    getNewMoiveName = myMovie & "." & extension 
End Function