對於目前測試字符串的位置x的

Question

在所涉及接收通過串行鏈路串最近的應用德爾福功能，我發現自己寫的代碼，如：爲了檢查某個特定子是在乞討

if (pos('needle', haystack) = 1) then ... 

一個字符串。

我猛然意識到POS機的功能是不理想的這個，因爲它根本不知道我在找哪個位置的子要英寸

是否有一個很好的功能，這是否？

是否有更通用的功能，如IsSubStringAt(needle, haystack, position)？

我沒想到用這樣的事情的：

function IsSubstrAt(const needle, haystack: string; position: Integer): Boolean; 
var 
    ii: integer; 
begin 
    result := true; 
    for ii := 1 to length(needle) de begin 
    if (haystack[poition + ii -1] <> needle[ii]) then begin 
     result := false; 
     break; 
    end; 
    end; 
end; 

一些錯誤檢查。

我希望找到一個準備好的滾動答案。

Answer 1

既然你只想看一個位置，你可以形成子串並測試它。就像這樣：

function IsSubStringAt(const needle, haystack: string; position: Integer): Boolean; 
var 
    substr: string; 
begin 
    substr := Copy(haystack, position, Length(needle)); 
    Result := substr = needle; 
end; 

如果性能是真正的關鍵，然後再你想不創建副本，並由此進行堆分配執行就地進行比較。你可以使用AnsiStrLComp這個。

function IsSubStringAt(const needle, haystack: string; position: Integer): Boolean; 
begin 
    if Length(haystack) - position + 1 >= Length(needle) then begin 
    Result := AnsiStrLComp(
     PChar(needle), 
     PChar(haystack) + position - 1, 
     Length(needle) 
    ) = 0; 
    end else begin 
    Result := False; 
    end; 
end; 

如果不想敏性檢查到的情況下，在第一個版本SameText替換=，並在第二版用AnsiStrLIComp替換AnsiStrLComp。

Answer 2

由於XE7你可以使用（假設位置基於1）：

function IsSubStringAt(const needle, haystack: string; position: Integer): Boolean; 
begin 
    result := string.Compare(hayStack, position-1, needle, 0, needle.Length) = 0; 
end; 

Answer 3

你可以使用CompareMem（）來直接比較字符串的內容：

function IsSubStringAt(const aNeedle, aHaystack: String; aPosition: Integer): Boolean; 
    var 
    needleLen: Integer; 
    begin 
    needleLen := Length(aNeedle); 
    result := (needleLen + aPosition - 1) <= Length(aHaystack); 

    if result then 
     result := CompareMem(Pointer(aNeedle), @aHaystack[aPosition], needleLen * sizeof(Char)); 
    end; 

請注意，我們的短期如果幹草堆太短而不能將針頭容納在指定位置，則需要進行比較。

使用CompareMem（） API確保實現是便攜，也將與一個Unicode 字符串類型，只要工作（你應該永遠遷移或德爾福的Unicode版本使用此代碼）的大小Char類型被考慮在內，就像這裏所做的那樣。

然而，這種方法假定字符串已經被規範化到所需要的任何程度，使得字符串的字節內容可以直接比較。

Answer 4

這是用匯編語言編寫的一個非常快速的方法。

Function PosS (Substr:string; S:string; Position:integer) : integer; 
    Asm 
    TEST EAX,EAX 
    JE  @@NoWork 

    TEST EDX,EDX 
    JE  @@StringEmpty 

    PUSH EBX 
    PUSH ESI 
    PUSH EDI 

    MOV  ESI, EAX       // Pointer to Substr 
    MOV  EDI, EDX       // Pointer to S 
    MOV  EBX, ECX       // Position 
    DEC  EBX 

    MOV  ECX, [EDI-4]      // Length (S) 
    SUB  ECX, EBX 

    PUSH EDI 
    ADD  EDI, EBX 

    MOV  EDX, [ESI-4]      // Length (Substr) 

    DEC  EDX 
    JS  @@Fail 
    MOV  AL, [ESI] 
    INC  ESI 

    SUB  ECX, EDX       // = Length (S) - Length (Substr) + 1 
    JLE  @@Fail 
@@Loop: 
    REPNE SCASB 
    JNE  @@Fail 
    MOV  EBX, ECX 
    PUSH ESI 
    PUSH EDI 

    MOV  ECX, EDX 
    REPE CMPSB 
    POP  EDI 
    POP  ESI 
    JE  @@Found 
    MOV  ECX, EBX 
    JMP  @@Loop 

@@Fail: 
    POP  EDX 
    XOR  EAX, EAX 
    JMP  @@Exit 

@@StringEmpty: 
    XOR  EAX, EAX 
    JMP  @@NoWork 

@@Found: 
    POP  EDX 
    MOV  EAX, EDI 
    SUB  EAX, EDX 
@@Exit: 
    POP  EDI 
    POP  ESI 
    POP  EBX 
@@NoWork: 
    End;