總結一個滑動窗口的數值列在另一列中的值

Question

我現在面臨的問題是用另一列中的值定義滑動窗口來總結數字列。

列表（1）的數據是製表符分隔的，用兩個數字列：

1000 12 
2000 10 
3000 9 
5000 3 
9000 5 
10000 90 
30000 20 
31000 32 
39000 33 
40000 28 

（2）欲與由第一列定義的窗口來總結第二列中，窗口大小爲（第1列+ 3000）。這意味着我需要添加第3列（第3列=總和（第1列的行中第2列的所有值到第1列+3000））。

它看起來像這樣：

1000 12 12+10+9 
2000 10 10+9+3 
3000 9 9 
5000 3 3 
9000 5 5+90 
10000 90 90 
30000 20 20+32 
31000 32 32 
39000 33 33 
40000 28 

（3）我是新編程。我嘗試過awk，但我失敗了。

不知如何控制窗口的第一列

AWK「（I = 1;我< = NR;我++）{總和[I] + = $ 2} END {打印$ 1，$ 2 ，sum}'mydata

任何人都可以給我任何關於這個問題的建議/方向？提前致謝。

最佳，

Answer 1

這不是真的任何語言真正擅長的東西，事實上你要求的是一個相當具有挑戰性的編程任務，尤其是對新手來說。

儘管如此，這裏是一個awk腳本，您：

BEGIN { 
    window = 3000; 
} 

function push(line, sum, n) { 
    n = length(lines); 
    lines[n] = line; 
    sums[n] = sum; 
} 

function pop( n, i) { 
    n = length(lines); 

    if (n > 1) { 
     for(i = 0; i < n - 1; i++) { 
      lines[i] = lines[i + 1]; 
      sums[i] = sums[i + 1]; 
     } 
    } 
    if (n > 0) { 
     delete lines[n - 1]; 
     delete sums[n - 1]; 
    } 
} 

{ 
    cur_line = $1; 
    value = $2; 
    n = length(lines); 
    pops = 0; 
    for (i = 0; i < n; i++) { 
     if (lines[i] + window < cur_line) { 
      print "Sum for " lines[i] " = " sums[i]; 
      pops++; 
     } 
    } 
    for (i = 0; i < pops; i++) { 
     pop(); 
    } 
    push(cur_line, 0); 
    n = length(lines); 
    for (i = 0; i < n; i++) { 
     sums[i] = sums[i] + value; 
    } 
} 

END { 
    n = length(lines); 
    for (i = 0; i < n; i++) { 
     if (lines[i] < cur_line + window) { 
      print "Sum for " lines[i] " = " sums[i]; 
     } 
    } 
} 

這裏對您的樣本數據的運行：

Sum for 1000 = 31 
Sum for 2000 = 22 
Sum for 3000 = 12 
Sum for 5000 = 3 
Sum for 9000 = 95 
Sum for 10000 = 90 
Sum for 30000 = 52 
Sum for 31000 = 32 
Sum for 39000 = 61 
Sum for 40000 = 28 

Answer 2

我不是很好的awk的，但這裏是我在Perl黑客在一起，如果你是在UNIX系統上也應該運行。假設你將它保存爲一個文件名爲window.pl：

#!/usr/bin/perl -w 
use strict; 

# Usage: window.pl < [filepath or text stream] 
# Example: window.pl < window.txt 

my $window = 3000; 
my @lines = <STDIN>; 
my $i = 0; 
my $last_line = $#lines; 

# Start reading each line 
while ($i<= $last_line) 
{ 
    my $current_line = $lines[$i]; 
    my ($col1, $col2) = ($current_line =~ /(\d+)\s+(\d+)/); 
    my $ubound = $col1 + $window; 
    my @sums = $col2; 
    my $lookahead = $i + 1; 

    # Start looking at subsequent lines within the window 
    while ($lookahead <= $last_line) 
    { 
     my $next_line = $lines[$lookahead]; 
     my ($c1, $c2) = ($next_line =~ /(\d+)\s+(\d+)/); 
     if ($c1 <= $ubound) 
     { 
      push @sums, $c2; 
      ++$lookahead; 
     } 
     else 
     { 
      last; 
     } 
    } 

    my $output; 
    if ($#sums > 0) 
    { 
     my $sum = join "+", @sums; 
     $output = "$col1 $sum\n"; 
    } 
    else 
    { 
     $output = "$col1 $col2\n"; 
    } 
    print $output; 
    ++$i; 
} 

輸出：

1000 12+10+9 
2000 10+9+3 
3000 9+3 
5000 3 
9000 5+90 
10000 90 
30000 20+32 
31000 32 
39000 33+28 
40000 28 

這隻能如果輸入文件足夠小，以讀入內存，但也許這將幫助你反正。

祝你好運！

Answer 3

這裏有一個解決方案的一個更爲簡潔的版本：

#!/usr/bin/perl 
use strict; 
use warnings; 

use constant WIN_SIZE => 3000; 

my @pending; 

while (<>) { 
    my ($pos, $val) = split; 

    # Store line info, sum, and when to stop summing 
    push @pending, { pos => $pos, 
        val => $val, 
        limit => $pos + WIN_SIZE, 
        sum => 0 }; 

    show($_) for grep { $_->{limit} < $pos } @pending; # Show items beyond window 

    @pending =  grep { $_->{limit} >= $pos } @pending; # Keep items still in window 

    $_->{sum} += $val for @pending;      # And continue their sums 
} 

# and don't forget those items left within the window when the data ran out 
show($_) for @pending; 

sub show { 
    my $pending = shift; 
    print join("\t", $pending->{pos}, $pending->{val}, $pending->{sum}), "\n"; 
} 

只需將其放在腳本中，並將數據文件放在同一行上，例如：

$ perl script.pl mydata 
1000 12 31 
2000 10 22 
3000 9 12 
5000 3 3 
9000 5 95 
10000 90 90 
30000 20 52 
31000 32 32 
39000 33 61 
40000 28 28 

Answer 4

這裏是一個Perl的解決方案：

use warnings; 
use strict; 

my (%data, @ids); 
while (<DATA>) { # read in the data 
    /^(\d+)\s+(\d+)$/ or die "bad input: $_"; 
    push @ids, $1; 
    $data{$1} = [$2] 
} 
for (0 .. $#ids) { # slide window over data 
    my ($i, $id) = ($_ + 1, $ids[$_]); 

    push @{$data{$id}}, $data{ $ids[$i++] }[0] 
     while $i < @ids and $ids[$i] <= $id + 3000; 
} 

$" = '+';                #" 
print "$_: @{$data{$_}}\n" for @ids; 

__DATA__ 
1000 12 
2000 10 
3000 9 
5000 3 
9000 5 
10000 90 
30000 20 
31000 32 
39000 33 
40000 28 

它打印：

 
1000: 12+10+9 
2000: 10+9+3 
3000: 9+3 
5000: 3 
9000: 5+90 
10000: 90 
30000: 20+32 
31000: 32 
39000: 33+28 
40000: 28