使用數組和在XSLT

Question

添加元素我有一些變量需要被比較，並且根據它們是否相等需要被添加到陣列中我的最大的問題是

一個。是一個很好的手段，這是一個很好的手段。

b。我如何將元素添加到數組中

另外我認爲需要很多ifs的權利。

<xsl:variable name="Monday"> 
    <xsl:apply-templates select="./OpeningHours/Monday"/> 
</xsl:variable> 
<xsl:variable name="Tuesday"> 
    <xsl:apply-templates select="OpeningHours/Tuesday"/> 
</xsl:variable> 
<xsl:variable name="Wednesday"> 
    <xsl:apply-templates select="OpeningHours/Wednesday"/> 
</xsl:variable> 
<xsl:variable name="Thursday"> 
    <xsl:apply-templates select="OpeningHours/Thursday"/> 
</xsl:variable> 
<xsl:variable name="Friday"> 
    <xsl:apply-templates select="OpeningHours/Friday"/> 
</xsl:variable> 
<xsl:variable name="Saturday"> 
    <xsl:apply-templates select="OpeningHours/Saturday"/> 
</xsl:variable> 
<xsl:variable name="Sunday"> 
    <xsl:apply-templates select="OpeningHours/Sunday"/> 
</xsl:variable> 

模板應用於數據

的

<xsl:template match="OpeningHours/*"> 
    <xsl:value-of select="Open + Close"/> 
</xsl:template> 

樣品

<OpeningHours> 
    <Monday> 
     <Open>8.5</Open> 
     <Close>20</Close> 
    </Monday> 
    <Tuesday> 
     <Open>8.5</Open> 
     <Close>20</Close> 
    </Tuesday> 
    <Wednesday> 
     <Open>8.5</Open> 
     <Close>20</Close> 
    </Wednesday> 
    <Friday> 
     <Open>8.5</Open> 
     <Close>22</Close> 
    </Friday> 
    <Saturday> 
     <Open>7</Open> 
     <Close>14</Close> 
    </Saturday> 
</OpeningHours> 

我最終的結果應該是

週一至週三8：30-20：00

星期五8：30-22：00

星期六7：00-14：00

Answer 1

使用XSLT 2.0，我認爲這是for-each-group group-adjacent工作：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:output method="text"/> 

<xsl:template match="OpeningHours"> 
    <xsl:for-each-group select="*" group-adjacent="concat(Open, '|', Close)"> 
    <xsl:value-of select="concat(substring(local-name(), 1, 3), 
           if (current-group()[2]) then concat('-', substring(local-name(current-group()[last()]), 1, 3)) else(), 
           ' ', Open, '-', Close, '&#10;')"/> 
    </xsl:for-each-group> 
</xsl:template> 

</xsl:stylesheet> 

然後，您可以編寫一個函數來格式化Open/Close。

Answer 2

下面的XSLT將完成您描述的大部分功能。我相信它可以變得更高效或更好，但它解決了基於開放日期打開哪些日子來組合的問題。

它不會將「8.5」作爲值重新分解爲「08:30」作爲小時格式。

<?xml version="1.0" encoding="UTF-8" ?> 
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 
    <xsl:output method='text' indent="yes"/> 

    <xsl:template match="OpeningHours"> 
     <xsl:apply-templates select="*" /> 
    </xsl:template> 

<!-- process if the element is a child of opening hours --> 
    <xsl:template match="OpeningHours/*"> 
     <xsl:choose> 

<!-- If the preceding Open or Close is different, or we are the firs element --> 
      <xsl:when test="Open != preceding-sibling::*/Open or Close != preceding-sibling::*/Close or position()=1"> 

     <!-- print out the first 3 characters of the name of the element --> 
       <xsl:value-of select='substring(local-name(.),1,3)'/> 

      <!-- if the next Open or Close are different --> 
       <xsl:if test="Open != following-sibling::*[1]/Open or Close != following-sibling::*[1]/Close or position()=last()"> 

      <!-- apply templates on "Open" and "Close" elements --> 
        <xsl:apply-templates select="*"/> 
       <xsl:text> 
</xsl:text> 
       </xsl:if> 
      </xsl:when> 

<!-- if the next Open or Close are diffent --> 
      <xsl:when test="Open != following-sibling::*[1]/Open or Close != following-sibling::*[1]/Close"> 

<!-- print a dash --> 
       <xsl:text>-</xsl:text>   

<!-- print 1st 3 leters of the element name *eg; Mon, Tue --> 
       <xsl:value-of select='substring(local-name(.),1,3)'/> 

<!-- Apply templates on "Open" & "Close" elements --> 
       <xsl:apply-templates select="*"/> 
       <xsl:text> 
</xsl:text> 
      </xsl:when> 
     </xsl:choose> 
    </xsl:template> 

<!-- when processing open or close elements, just print the value of the content --> 
    <xsl:template match="Open"> 
     <xsl:value-of select='.'/> 
    </xsl:template> 
    <xsl:template match="Close"> 
     <xsl:text>-</xsl:text> 
     <xsl:value-of select='.'/> 
    </xsl:template> 


<!-- copy any other node/attribute --> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:transform> 

希望這有助於