根據屬性值

Question

德爾福RTTI設定值I類有這樣

TuserClass = class 
private 
FUtilisateurCode: string; 
FUtilisateurCle: string; 
public 
procedure SetCodeInt(ACode: string; AValue: string); 
published 
[CodeInt('2800')] 
property UtilisateurCode: String read FUtilisateurCode write FUtilisateurCode; 
[CodeInt('2801')] 
property UtilisateurCle: String read FUtilisateurCle write FUtilisateurCle; 
end; 

procedure TuserClass.SetCodeInt(ACode: string; AValue: string); 
begin 
    // what I want to is making this by RTTI to set good value to good CodeInt 
    if ACode = '2800' then FutilisateurCode := AValue 
    else if ACode = '2801' then FUtilisateurCle := AValue; 
end; 

我想用我的SetCodeInt程序，以填補我的財產的價值，但我有問題。 我需要做什麼？

Answer 1

需要自定義屬性類：

type 
    CodeIntAttribute = class(TCustomAttribute) 
    private 
    FValue: Integer; 
    public 
    constructor Create(AValue: Integer); 
    property Value: Integer read FValue; 
    end; 
.... 
constructor CodeIntAttribute.Create(AValue: Integer); 
begin 
    inherited Create; 
    FValue := AValue; 
end; 

我選擇做價值，這似乎不是一個字符串比較合適的整數。

然後定義的屬性是這樣的：

[CodeInt(2800)] 
property UtilisateurCode: string read FUtilisateurCode write FUtilisateurCode; 
[CodeInt(2801)] 
property UtilisateurCle: string read FUtilisateurCle write FUtilisateurCle; 

最後的SetCodeInt實現如下：

procedure TUserClass.SetCodeInt(ACode: Integer; AValue: string); 
var 
    ctx: TRttiContext; 
    typ: TRttiType; 
    prop: TRttiProperty; 
    attr: TCustomAttribute; 
    codeattr: CodeIntAttribute; 
begin 
    typ := ctx.GetType(ClassType); 
    for prop in typ.GetProperties do 
    for attr in prop.GetAttributes do 
     if attr is CodeIntAttribute then 
     if CodeIntAttribute(attr).Value=ACode then 
     begin 
      prop.SetValue(Self, TValue.From(AValue)); 
      exit; 
     end; 
    raise Exception.CreateFmt('Property with code %d not found.', [ACode]); 
end;