檢查是否兩個列表至少有一個共同的項目

Question

如果有兩個列表：

Dim list1 As New List(Of Integer) 
list1.AddRange({1, 2, 3}) 

Dim list2 As New List(Of Integer) 
list2.AddRange({1, 4, 5}) 

什麼是VB.NET的最佳途徑，在性能方面，以檢測他們是否有一個或多個公共項目？儘可能地這應該是通用的。

Answer 1

<System.Runtime.CompilerServices.Extension()> _ 
Function ContainsAny(Of T)(col1 As IEnumerable(Of T), col2 As IEnumerable(Of T)) As Boolean 
    ' performance checks 
    If col1 Is Nothing OrElse col2 Is Nothing Then Return False 
    If col1 Is col2 Then Return True 
    ' compare items, using the smallest collection 
    If col1.Count < col2.Count Then 
     Dim hs1 As New HashSet(Of T)(col1) 
     For Each v In col2 
      If hs1.Contains(v) Then Return True 
     Next 
    Else 
     Dim hs2 As New HashSet(Of T)(col2) 
     For Each v In col1 
      If hs2.Contains(v) Then Return True 
     Next 
    End If 
    Return False 
End Function 

代碼示例：

Dim list1 As New List(Of Integer) 
list1.AddRange({1, 2, 3}) 

Dim list2 As New List(Of Integer) 
list2.AddRange({1, 4, 5}) 

Dim anyMatch As Boolean = list1.ContainsAny(list2) 

Answer 2

在C＃中（但在VB以及可能有效）

list1.Intersect(list2).Any()