默認情況下，如何在Outlook中放置邊框圓形圖像

Question

這是幾個月來令我煩惱的東西，如果不是幾年。將圖像粘貼到Outlook電子郵件時，它沒有邊框。我可以通過右鍵單擊圖片並選擇格式圖片來添加這些內容，也可能有一種工具可以執行此操作。我的問題是：有沒有辦法確保所有粘貼的圖像都有邊框？如果有Outlook的CSS樣式表，我可以在這裏做;或者也許有某個地方的設置？

在此先感謝！

Answer 1

你可以考慮提供一個VBA宏（加上鍵快捷鍵）。 不知道這是如何工作的圖像邊界，但對於在這裏電子郵件文本選擇是一個簡單的例子：

Sub ChangeSelectedExample() 
    Set insp = Application.ActiveInspector 
    If insp.CurrentItem.Class = olMail Then 
     Set mail = insp.CurrentItem 
     If insp.EditorType = olEditorHTML Then 
      txt = ActiveInspector.HTMLEditor.Selection.CreateRange.Text 
        ActiveInspector.HTMLEditor.Selection.CreateRange.Text = txt & "<hello world 1>" 
     ElseIf insp.EditorType = olEditorWord Then 
      txt = insp.CurrentItem.GetInspector.WordEditor.Application.Selection.Text 
        insp.CurrentItem.GetInspector.WordEditor.Application.Selection = txt & "<hello world 2>" 
     Else 
      MsgBox ("not supported mail format") 
     End If 
    Else 
     MsgBox ("not supported view type") 
    End If 
End Sub 

Answer 2

我有一個Word 2010中宏，增加了一個邊界圖像和中間他們：

Sub AddBlueBorderAndCenterImages() 
    Dim oIshp As InlineShape 
    Dim oshp As Shape 

    For Each oIshp In ActiveDocument.InlineShapes 'in line with text 
     With oIshp.Borders 
      .OutsideLineStyle = wdLineStyleSingle 
      .OutsideLineWidth = wdLineWidth025pt 
      .OutsideColor = RGB(0, 112, 192) 
     End With 
     oIshp.Select 
     Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter 
    Next oIshp 

    For Each oshp In ActiveDocument.Shapes 'floating with text wraped around 
     With oshp.Line 
      .Style = msoLineSingle 
      .Weight = 0.25 
      .ForeColor.RGB = RGB(0, 112, 192) 
     End With 
    Next oshp 

    Selection.HomeKey Unit:=wdStory 'go back to top of doc 
End Sub 

我試着將它調整到Outlook，最主要的是試圖從Outlook項目到Word的ActiveDocument。

因此，這裏的展望版本（無任何居中）：

Sub AddBlueBorders() 
    Set insp = Application.ActiveInspector 
    If insp.CurrentItem.Class = olMail Then 
     Set mail = insp.CurrentItem 
     If insp.EditorType = olEditorWord Then 
      Set wordActiveDocument = mail.GetInspector.WordEditor 

      For Each oIshp In wordActiveDocument.InlineShapes 'in line with text 
       With oIshp.Borders 
        .OutsideLineStyle = wdLineStyleSingle 
        '.OutsideLineWidth = wdLineWidth025pt ' error: one of the values passed to this method or property is out of range 
        .OutsideColor = RGB(0, 112, 192) 
       End With 
      Next oIshp 

      For Each oshp In wordActiveDocument.Shapes 'floating with text wraped around 
       With oshp.Line 
        .Style = msoLineSingle 
        .Weight = 0.25 
        .ForeColor.RGB = RGB(0, 112, 192) 
       End With 
      Next oshp 

     'ElseIf insp.EditorType = olEditorHTML Then 
     'Something else here, maybe using css? 

     End If 
    End If 
End Sub 

出於某種原因，這並不邊框添加到一個公司的標誌我有我的簽名，也許是因爲它在頁腳或其他文件部分。

這不是默認設置，它不會在圖像被粘貼/添加到電子郵件時自動添加邊框。您仍然必須將此宏與按鈕或快捷鍵相關聯。但希望它能幫助，甚至4個月後。

依稀從http://en.allexperts.com/q/Microsoft-Word-1058/Word-resize-pictures.htm