VBA Excel中獲取文件路徑 - 不工作

Question

我一直在使用下面的代碼在Excel中指定的文件夾路徑：

Set diaFolder = Application.FileDialog(msoFileDialogFolderPicker) 
diaFolder.AllowMultiSelect = False 
diaFolder.Show 

我會導出PDF文件（通過VBA代碼），這條道路。當我在Windows XP上運行Excel 2007時，此代碼完美無瑕。我最近升級了我的操作系統和辦公版本，現在我的Excel 2010在Windows 7上運行。代碼不再像以前那樣工作，問題是每次運行代碼時路徑都會一直向上移動一個級別。

例如，假設我選擇以下路徑：

\users\AK\Desktop\Projects\ProjectM

實際的PDF文件被保存在\users\AK\Desktop\Projects\

如果我選擇：\users\AK\Desktop\Projects\ PDF文件被保存在\users\AK\Desktop\

如果我繼續運行代碼，它會一直跳到一個級別，所以讓我說我連續運行3次（沒有選擇我的路徑）我的PDF文件將存儲在：\ users \ AK \

我不知道它是一個Excel 2010問題或Windows 7問題。有沒有人遇到過這個？

編輯：包括全碼：

Private Sub CODERUN() 
    ' Define values 
    FN_A = Cells(2, 2).Value 

    ' Print PDF version 
    Set diaFolder = Application.FileDialog(msoFileDialogFolderPicker) 
    diaFolder.AllowMultiSelect = False 
    diaFolder.Show 

    ' Print PDF version 
    Sheets("Part A").Select 
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, filename:=FN_A & "_A", _ 
            Quality:=xlQualityStandard, _ 
            IncludeDocProperties:=True, _ 
            IgnorePrintAreas:=False, _ 
            OpenAfterPublish:=False 
End Sub 

Answer 1

我明白你問什麼，因爲我已經打了同樣的問題。我相信你的問題是，如果你運行你有的代碼，然後在對話框中點擊取消或確定，那麼下次運行代碼時，初始路徑與前一個初始路徑相距一個水平。發生這種情況的原因是因爲對話框沒有放在尾部\，然後截斷到下一個\的路徑。因此，每次使用對話框時，都會在路徑中失去一個級別。

以下代碼應該適用於您，並且您可以接受或取消，直到您的心在沒有初始目錄更改的情況下爲止。

Private Sub CODERUN() 
    Dim sFilePath as String 

    ' Define values 
    FN_A = Cells(2, 2).Value 

    ' Print PDF version 
    With Application.FileDialog(msoFileDialogFolderPicker) 
     .AllowMultiSelect = False 
     If .Show = -1 Then 
      sFilePath = .SelectedItems(1) & "\" 
      .InitialFileName = sFilePath '<--Remove this line to see the problem 
     End If 
    End With 

    ' Print PDF version 
    Sheets("Part A").ExportAsFixedFormat Type:=xlTypePDF, filename:=sFilePath & FN_A & "_A", _ 
            Quality:=xlQualityStandard, _ 
            IncludeDocProperties:=True, _ 
            IgnorePrintAreas:=False, _ 
            OpenAfterPublish:=False 
End Sub