如何在Windows中啓動另一個進程時啓動進程？

我想創建一個方法來檢查某個程序是否正在運行 - 如果是，請啓動另一個程序。如何在Windows中啓動另一個進程時啓動進程？

這是我在英美菸草

@ECHO OFF 
:LOOP 
tasklist /nh /fi "imagename eq steam.exe" | find /i "steam.exe" >nul && START "" "C:\Program Files\TeamSpeak 3 Client\ts3client_win64.exe" || goto :LOOP

進展，我創建在Windows啓動時，基本上開始BAT（這是唯一的，以確保該批處理文件不可見的控制檯窗口中運行）一個VBS：

Set WshShell = CreateObject("WScript.Shell") 
WshShell.Run chr(34) & "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\if Steam running then TS.bat" & Chr(34), 0 
Set WshShell = Nothing

我的問題是，這樣做，我得到了令人難以置信的高CPU使用率（與I5-4670k 20至60％）。

我做錯了什麼？或者我可以改進代碼嗎？我正在考慮放慢窗口檢查過程的時間（即等待2秒鐘然後檢查），但我對編碼真的很陌生，對於如何這樣做我沒有任何想法。

我知道我的英語並不完美，對不起。

編輯：如果有幫助，我的電腦在Windows 10

來源

2015-12-01 XenSide

作爲另一種選擇，我相信微軟應用程序兼容性工具包能爲你做到這一點。 –

運行我得到一個令人難以置信的高CPU使用率

你需要給你的電腦檢查之間休息。所述timeout命令中斷批處理執行用於可配置數目的秒：

@echo off 
setlocal 

set "FIND_STEAM=tasklist /nh /fi "imagename eq steam.exe" ^| find /i "steam.exe" ^> NUL" 
set "START_TS=start "C:\Program Files\TeamSpeak 3 Client\ts3client_win64.exe"" 

:LOOP 

timeout 5 > NUL 
%FIND_STEAM% && %START_TS% || goto LOOP

EDIT

這裏是鐘聲和 - 口哨使用反應以在Windows一個過程的開始和終止的複雜的方式VBScript中。

它可以與WMI，一個強大的框架，可以在Windows中做各種事情。在這裏，我們使用它來監聽進程創建和進程終止事件。（監聽事件是很多比輪詢更高效的所有進程每秒左右）：

Option Explicit 

Dim WMIService, ProcessNew, ProcessEnd 
Dim computer, query, teamspeakPID 

' create a WMI service object and ProcessNew/ProcessEnd event sinks 
computer = "." 
Set WMIService = GetObject("winmgmts:\\" & computer & "\root\CIMV2") 
Set ProcessNew = WScript.CreateObject("WbemScripting.SWbemSink", "ProcessNew_") 
Set ProcessEnd = WScript.CreateObject("WbemScripting.SWbemSink", "ProcessEnd_") 

' we will be waiting for Win32_Process creation events and notify event sink "ProcessNew" 
WMIService.ExecNotificationQueryAsync ProcessNew, _ 
    "SELECT * FROM __InstanceCreationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'" 

' we will also be waiting for Win32_Process deletion events and notify event sink "ProcessEnd" 
WMIService.ExecNotificationQueryAsync ProcessEnd, _ 
    "SELECT * FROM __InstanceDeletionEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'" 

' main loop: nothing to do, we just sit and wait 
While True 
    Wscript.Sleep(500) 
Wend 

' function that handles "process created" events 
Sub ProcessNew_OnObjectReady(latestEvent, asyncContext) 
    Dim process 
    If LCase(latestEvent.TargetInstance.Name) = "steam.exe" Then 
     ' start TeamSpeak 
     Set process = GetObject("winmgmts:Win32_Process") 
     process.Create "C:\Program Files\TeamSpeak 3 Client\ts3client_win64.exe", null, null, teamspeakPID 
    End If 
End Sub 

' function that handles "process ended" events 
Sub ProcessEnd_OnObjectReady(latestEvent, asyncContext) 
    Dim processList, process 
    If LCase(latestEvent.TargetInstance.Name) = "steam.exe" Then 
     ' kill TeamSpeak (but only the one we started earlier) 
     Set processList = WMIService.ExecQuery("SELECT * FROM Win32_Process WHERE Name = 'ts3client_win64.exe' AND ProcessId = " & teamspeakPID) 
     For Each process in processList 
      process.Terminate() 
     Next 
    End If 
End Sub

作爲練習，你可以嘗試擴展這一點，以便它只有當它尚未運行啓動TS。

如何在Windows中啓動另一個進程時啓動進程？

回答

相關問題