爲什麼我要表達期待？

Question

這是一個重定向至不同的「會員區」頁面的用戶名和密碼登錄表單我簡單的CodeFile VB代碼：

Public Class MyPage 
Inherits Page 
Private Structure Cred 
    Public Username As String 
    Public Password As String 
    Public RedirectUrl As String 
    Public Sub New(un As String, pw As String, Optional ru As String = "/admin/default.aspx") 
     Username = un 
     Password = pw 
     RedirectUrl = ru 
    End Sub 
End Structure 

Private ReadOnly _credentials As System.Collections.Generic.IEnumerable(Of Cred) = New Cred(){New Cred("userone", "passwordone"), New Cred("usertwo", "passwordtwo"), New Cred("userthree", "passwordthree", "/admin/custom.aspx")} 

Public Sub Page_Load(sender As Object, e As EventArgs) 
    Dim user = _credentials.SingleOrDefault(Function(x) x.Username = UserName.Text AndAlso x.Password = Password.Text) 
    If user IsNot Nothing Then 
     Session("Admin") = True 
     Response.Redirect(user.RedirectUrl) 
    Else 
     Session("Admin") = False 
     LtlLogin.Text = "<p>Sorry, you have provided incorrect login details.</p>" 
    End If 
End Sub 
End Class 

它的上線：

Dim user = _credentials.SingleOrDefault(Function(x) x.Username = UserName.Text AndAlso x.Password = Password.Text) 

非常感謝。

大衛。

Answer 1

問題是您使用structure針對class針對Cred。 請注意，結構是值類型，類是引用類型。

所以：

Dim user = _credentials.SingleOrDefault(Function(x) x.Username = UserName.Text AndAlso x.Password = Password.Text) 

始終返回結構（沒事的時候發現，則結構的成員獲得其默認值）。

爲TI爲引用類型，你不能比較沒有的結構。

更改結構類，你會被罰款。

或更改與檢查：

If Not user.Equals(New Cred) Then 

檢查this

更新與實例

類中房

Imports System.Linq 

Module StartupModule 

    Private ReadOnly _credentials As System.Collections.Generic.IEnumerable(Of Cred) = New Cred() { 
     New Cred("userone", "passwordone"), 
     New Cred("usertwo", "passwordtwo"), 
     New Cred("userthree", "passwordthree", "/admin/custom.aspx")} 

    Sub Main() 
     Dim userName As String = "" 
     Dim password As String = "" 

     Dim crd = _credentials.Where(Function(x) x.Username = userName AndAlso x.Password = password).SingleOrDefault 

     If crd Is Nothing Then 
      Console.WriteLine("user is nothing") 
     Else 
      Console.WriteLine("user is something") 
     End If 


     Console.ReadLine() 
    End Sub 

    Private Class Cred 
     Public Username As String 
     Public Password As String 
     Public RedirectUrl As String 
     Public Sub New(un As String, pw As String, Optional ru As String = "/admin/default.aspx") 
      Username = un 
      Password = pw 
      RedirectUrl = ru 
     End Sub 
    End Class 


End Module 

結構中房

Imports System.Linq 

Module StartupModule 

    Private ReadOnly _credentials As System.Collections.Generic.IEnumerable(Of Cred) = New Cred() { 
     New Cred("userone", "passwordone"), 
     New Cred("usertwo", "passwordtwo"), 
     New Cred("userthree", "passwordthree", "/admin/custom.aspx")} 

    Sub Main() 
     Dim userName As String = "" 
     Dim password As String = "" 

     Dim crd = _credentials.Where(Function(x) x.Username = userName AndAlso x.Password = password).SingleOrDefault 

     If crd.Equals(New Cred) Then 
      Console.WriteLine("user is nothing") 
     Else 
      Console.WriteLine("user is something") 
     End If 


     Console.ReadLine() 
    End Sub 

    Private Structure Cred 
     Public Username As String 
     Public Password As String 
     Public RedirectUrl As String 
     Public Sub New(un As String, pw As String, Optional ru As String = "/admin/default.aspx") 
      Username = un 
      Password = pw 
      RedirectUrl = ru 
     End Sub 
    End Structure 


End Module