的Flex AdvancedDataGrid

Question

我想設置所選項目漸變背景在我AdvancedDataGrid

我該怎麼辦呢？

非常感謝 弗拉基米爾

Answer 1

你可以擴展AdvancedDataGrid如下面的例子：

import flash.display.GradientType; 
import flash.display.Graphics; 
import flash.display.Sprite; 
import flash.geom.Matrix; 
import mx.controls.AdvancedDataGrid; 
import mx.controls.listClasses.IListItemRenderer; 
import mx.core.mx_internal; 

use namespace mx_internal; 
public class CustomAdvancedDataGrid extends AdvancedDataGrid 
{ 
    public var secondaryColor : uint = 0xFFFFFF; 

    protected override function drawSelectionIndicator(
     indicator:Sprite, x:Number, y:Number, 
     width:Number, height:Number, color:uint, 
     itemRenderer:IListItemRenderer) : void 
    { 
     if (isRowSelectionMode()) 
      width = unscaledWidth - viewMetrics.left - viewMetrics.right; 

     var mat : Matrix = new Matrix(); 
     mat.createGradientBox(width,height,-90*Math.PI/180); 

     var g:Graphics = Sprite(indicator).graphics; 
     g.clear(); 
     g.beginGradientFill(GradientType.LINEAR, [color, secondaryColor], [1, 1], [0, 255], mat); 
     g.drawRect(0, 0, width, height); 
     g.endFill(); 

     indicator.x = x; 
     indicator.y = y; 
    } 
} 

其他功能，你可以考慮重寫爲：drawHighlightIndicator和drawCaretIndicator（其具有相同的結構）。至於secondaryColor，您可以將其保留爲硬編碼，或爲其定義樣式。