Excel VBA函數：如何通過範圍，轉換爲數組，反轉，並返回數組

Question

我想在Excel中做一些數組運算，這需要我反轉一定數量的一維範圍很多次，所以我想爲它編寫一個函數，而不是在電子表格中創建反轉。我在VBA中寫了一個reverse（）函數，但它返回#VALUE！電子表格中的錯誤。無論數組大小如何，也不管是輸入相同大小的數組函數，還是使用SUM（）等彙總函數進行封裝。我證實了倒車邏輯可以作爲一個Sub。這導致我相信問題是傳遞/返回範圍/數組，但我不明白什麼是錯的。

Function reverse(x As Range) As Variant() 
' Array formula that reverses a one-dimensional array (1 row, x columns) 
    Dim oldArray() As Variant, newArray() As Variant 
    Dim rows As Long: i = x.rows.Count 
    Dim cols As Long: i = x.Columns.Count 
    ReDim oldArray(1 To rows, 1 To cols), newArray(1 To rows, 1 To cols) 

    oldArray = x.Value 
    newArray = oldArray 

    For i = 1 To cols/2 Step 1 
     newArray(1, i) = oldArray(1, cols - i + 1) 
     newArray(1, cols - i + 1) = oldArray(1, i) 
    Next 

    reverse = newArray 
End Function 

請記住，我可以擴展它來反轉二維數組，但這是微不足道的部分。我的問題是試圖確保函數在（1，N）範圍內工作。

謝謝！

Answer 1

查找下面的代碼....

Function reverse(x As Range) As Variant() 
' Array formula that reverses a one-dimensional array (1 row, x columns) 
    Dim oldArray() As Variant, newArray() As Variant 
    Dim rows As Long 
    rows = x.rows.Count 
    Dim cols As Long 
    cols = x.Columns.Count 
    ReDim oldArray(1 To rows, 1 To cols), newArray(1 To rows, 1 To cols) 

    oldArray = x.Value 
    newArray = oldArray 

    For i = 1 To cols/2 Step 1 
     newArray(1, i) = oldArray(1, cols - i + 1) 
     newArray(1, cols - i + 1) = oldArray(1, i) 
    Next 
reverse = newArray 
End Function 

Answer 2

這將扭轉列無論行數範圍內。

Function reverse(Source As Range) As Variant() 
    Dim Data, RevData 
    Dim x As Long, y As Long, y1 As Long 

    Data = Source.Value 

    ReDim RevData(1 to UBound(Data, 1),1 to UBound(Data, 2)) 

    For x = 1 To UBound(Data, 1) 
     y1 = UBound(Data, 2) 
     For y = 1 To UBound(Data, 2) 
      RevData(x, y1) = Data(x, y) 
      y1 = y1 - 1 
     Next 
    Next 
    reverse = RevData 
End Function 

Answer 3

以下代碼更通用，它使用可選參數來確定是否應顛倒行，列或兩者（或無）。默認情況下，它會反轉列。

Function ReverseRange(Source As Range, Optional ReverseRows As Boolean = False, Optional ReverseColumns As Boolean = True) As Variant() 
    Dim SourceArray() As Variant 
    Dim DestArray() As Variant 
    SourceArray = Source.value 

    Dim nRows As Long, nColumns As Long 
    nRows = UBound(SourceArray, 1) 
    nColumns = UBound(SourceArray, 2) 
    ReDim DestArray(1 To nRows, 1 To nColumns) 

    Dim r As Long, r2 As Long, c As Long, c2 As Long 
    For r = 1 To nRows 
     r2 = IIf(ReverseRows, nRows - r + 1, r) 
     For c = 1 To nColumns 
      c2 = IIf(ReverseColumns, nColumns - c + 1, c) 
      DestArray(r2, c2) = SourceArray(r, c) 
     Next c 
    Next r 
    ReverseRange = DestArray 
End Function 

請注意，範圍有效性沒有驗證。