如何編輯Winrar窗口資源管理器中的.bat文件？

Question

Has Winrar另一種直接在資源管理器中編輯bat文件的方法？

我點擊一個zip文件它向我展示一個帶有許多文件的Winrar彈出窗口，雙擊某個文件在默認程序中打開它（記事本++中的.txt，蟾蜍中的.sql等），但雙擊蝙蝠文件運行蝙蝠。 Alt + v是查看文件的快捷方式，但它不允許我編輯bat文件。

唯一的方法是將文件拖到Windows，編輯並拖回到Windows。

Answer 1

WinRAR的具有該功能暫時提取雙次點擊文件臨時文件文件夾選項卡上的定義路徑在設置從菜單選項打開，然後啓動與該文件關聯的應用程序，並且在開始應用程序終止之後，如果修改該文件，則將該文件重新包裝到歸檔中。

，這也是做了可執行文件除了選擇文件類型，以從標籤提取安全排除從菜單中選項開幕，提取默認整個歸檔下定義設置啓用在標籤上打開的所有內容查看器的設置。

但雙擊的默認行爲可以在標籤上自定義查看器的設置。選擇有後提出的代替內部查看爲瀏覽器類型和進入C:\Windows\Notepad.exe爲外部觀察者名裏面的存檔結果的* .bat文件，雙擊在提示用戶輸入與內部或外部的觀衆觀看或用相關程序打開文件。當然*.bat不應該在設置列表解壓一切爲。

現在點擊按鈕外部瀏覽器（記事本）批處理文件提取到臨時文件文件夾，然後記事本啓動與該文件查看和編輯。當完成查看/編輯批處理文件並退出記事本,WinRAR檢測到修改並詢問用戶是否應在檔案中更新修改後的文件。

有按鈕幫助每個設置對話框。請使用它，並在WinRAR的幫助下閱讀。

如果檔案文件內的所有批處理文件都應該被編輯，我建議儘可能使用批處理文件自動執行此任務。

@echo off 
setlocal 
set "FileToEdit=Test.bat" 
set "PathInArchive=" 
set "DefaultArchive=C:\Temp\Test.zip" 

rem Set a title for the command prompt window and determine name 
rem of this batch file with full path for a possible error message. 
title Update %FileToEdit% 
set "BatchFile=%~f0" 

rem Use a standard archive file if none is specified as first parameter. 
if "%~1"=="" (
    set "ArchiveFile=%DefaultArchive%" 
) else (
    set "ArchiveFile=%~f1" 
) 

rem Test if the archive file exists at all. 
if not exist "%ArchiveFile%" (
    call :ErrorMessage "Archive file %ArchiveFile% does not exist." 
    exit /B 
) 

rem Make sure path in archive ends with a backslash 
rem if a path to file in archive is defined at all. 
if not "%PathInArchive%" == "" (
    if not "%PathInArchive:~-1%" == "\" (
     set "PathInArchive=%PathInArchive%\" 
    ) 
) 

rem Extract the file to edit to directory for temporary files. 
"%ProgramFiles%\WinRAR\WinRAR.exe" e -cfg- -ibck -y -- "%ArchiveFile%" "%PathInArchive%%FileToEdit%" "%TEMP%\" 
if errorlevel 1 (
    call :ErrorMessage "Failed to extract file %PathInArchive%%FileToEdit%" 
    exit /B 
) 

rem Start Windows Notepad to edit the temporary extracted file. 
start "" /wait %windir%\Notepad.exe "%TEMP%\%FileToEdit%" 

rem Define the option -ap with path in archive if needed at all. 
set "ArchivePath=" 
if not "%PathInArchive%" == "" set "ArchivePath=-ap"%PathInArchive%"" 

rem Update the edited file in archive and delete it on success. 
"%ProgramFiles%\WinRAR\WinRAR.exe" u %ArchivePath% -cfg- -df -ibck -ep -y -- "%ArchiveFile%" "%TEMP%\%FileToEdit%" 
if errorlevel 1 (
    del "%TEMP%\%FileToEdit%" 2>nul 
    call :ErrorMessage "Failed to update file %PathInArchive%%FileToEdit%" 
    exit /B 
) 

rem Exit batch processing. 
exit /B 

rem Subroutine to output an error message. 
:ErrorMessage 
echo Error detected by: %BatchFile% 
echo On processing file: %ArchiveFile% 
echo. 
echo Error: %~1 
echo. 
endlocal 
pause 
exit /B 

在批處理文件的頂部分配給變量FileToEdit，PathInArchive和DefaultArchive的值應該被適當地限定。

通過用合適的名稱創建在的SendTo夾%USERPROFILE%的子文件夾的快捷方式（* .LNK）到這個批處理文件，在一個歸檔文件右擊與批處理文件具有固定的名稱和路徑修改內部存檔和點擊子菜單發送到在這個快捷方式的結果提取批處理文件臨時文件到文件夾，打開窗戶記事本進行編輯和重新包裝最後修改的批處理文件導入存檔文件之後。

打開幫助主題在菜單幫助在WinRAR的並點擊選項卡內容上項目命令行模式。此內容列表項下的幫助頁面說明使用命令e和u以及所使用的開關。

爲了解所使用的命令及其工作方式，請打開命令提示符窗口，在其中執行以下命令，並仔細閱讀爲每個命令顯示的所有幫助頁面。

• call /?
• del /?
• echo /?
• endlocal /?
• exit /?
• if /?
• pause /?
• rem /?
• set /?
• setlocal /?
• start /?
• title /?

Answer 2

1. 從WinRAR的，單擊選項 - >設置 - >瀏覽器。

2. 激活向「到瀏覽器類型。

3. 粘貼%WINDIR%\notepad.exe或你最喜歡的編輯器中外部觀察者名路徑。

4. 點擊確定。完成。

現在，當你雙擊存檔中的任何非exe文件，彈出讓你選擇如何打開它：

• 內部

• 外部（通過記事本或你的編輯器）

• 相關的程序