Excel報告 - 公式VBA

Question

我在使用VB6構建報告時遇到了一些問題。基本上，我正在構建一個動態報告，其中標題和2列（客戶端，學生）從記錄集中填充。正如您在圖片中看到的，在我的標題末尾，我添加了一個TOTAL標題，下面有客戶和學生。我試圖讓每個專欄中的所有客戶總數達到TOTAL，與學生一樣。列數（UCLA，SDU，SCCU）可能會有所不同，所以我試圖讓它變成動態的。基本上從A開始，然後是B，然後是C，D和NONE。有任何想法嗎？ 編輯：我請從SQL SERVER的SHORT LABEL和填充直到g_RS3是空

Do While Not g_RS3.EOF 
    With xlSheet.Cells(xlRow, xlCol) 
     .Value = g_RS3("ShortLabel") 
      .Offset(1, 0).Value = " Clients " 
      .Offset(1, 1).Value = " Students" 
       With .Offset(1, 0) 
        .Font.Bold = True 
       .Borders.Weight = xlThin 
      End With 
      With .Offset(1, 1) 
       .Font.Bold = True 
       .Borders.Weight = xlThin 
      End With 
      With .Resize(1, 2) 
       .Font.Bold = True 
       .WrapText = True 
       .VerticalAlignment = xlCenter 
       .Merge 
       .HorizontalAlignment = xlCenter 
       .Borders.Weight = xlThin 
      End With 
    End With 
    xlCol = xlCol + 2 
    g_RS3.MoveNext 
Loop 
With xlSheet.Cells(xlRow, xlCol) 
    .Value = "TOTAL" 
     .Offset(1, 0).Value = "Clients" 
     .Offset(1, 1).Value = "Students" 
      With .Offset(1, 0) 
       .Font.Bold = True 
      .Borders.Weight = xlThin 
     End With 
     With .Offset(1, 1) 
      .Font.Bold = True 
      .Borders.Weight = xlThin 
     End With 
     With .Resize(1, 2) 
      .Font.Bold = True 
      .WrapText = True 
      .VerticalAlignment = xlCenter 
      .Merge 
      .HorizontalAlignment = xlCenter 
      .Borders.Weight = xlThin 
     End With 
End With 

然後我開始xlrow = 4 xlcol = 2和填充數據在客戶端和STUDENT列。我擁有的循環相當長。但用戶只會查看摘錄。一旦它的產生取決於他們，他們用它做什麼。該應用程序爲他們提供了添加SHORTLABEL的選項，一旦它們生成，SHORTLABEL需要在提取中顯示。

Answer 1

SUMIF function或SUMIFS function可以方便地執行此操作。

在H4作爲標準公式，

=sumifs($b4:$g4, $b$3:$g$3, h$3) 

填寫兩個向右和向下。

在VBA作爲，

with worksheets("Sheet1") 
    .range("H4:I8").formula = "=sumifs($b4:$g4, $b$3:$g$3, h$3)" 
    'optional revert to values only 
    '.range("H4:I8") = .range("H4:I8").values 
end with 

您必須確定客戶端/學生的程度範圍，但有一半做法僅僅是知道放在哪裏公式（例如H4）。

VBA

我已經刪除了很多所使用的原代碼的冗餘。考慮到您尚未將數據填充到客戶端/學生列中，我使用了一種方法，其中Total列（s）總是寫入右側的公式。如果還有另外一組行，那麼總計將被覆蓋，並在右側創建一個新行。

Dim xlStartCol As Long 
xlStartCol = xlCol 
Do While Not g_RS3.EOF 
    With xlSheet.Cells(xlRow, xlCol) 
     .Resize(1, 2).Merge 
     .Value = "TEST" 'g_RS3("ShortLabel") 
     .Offset(1, 0).Resize(1, 2) = Array("Clients", "Students") 
     .Offset(2, 0).Resize(1, 2).ClearContents 
     With .Offset(0, 1) 
      .Resize(1, 2).Merge 
      .Value = "Total" 'keep writing Total to the right; it will be overwritten if there is another ShortLabel 
      .Offset(1, 0).Resize(1, 2) = Array("Clients", "Students") 
      .Offset(2, 0).Resize(1, 2).Formula = _ 
       "=SUMIFS(" & Range(.Parent.Cells(xlRow + 2, xlStartCol), .Parent.Cells(xlRow + 2, xlCol + 1)).Address(0, 1) & Chr(44) & _ 
          Range(.Parent.Cells(xlRow + 1, xlStartCol), .Parent.Cells(xlRow + 1, xlCol + 1)).Address(1, 1) & Chr(44) & _ 
          .Parent.Cells(xlRow + 1, xlCol - 1).Address(1, 0) & Chr(41) 
     End With 
     With .Resize(2, 4) 
      .Font.Bold = True 
      .VerticalAlignment = xlCenter 
      .HorizontalAlignment = xlCenter 
      .Borders.Weight = xlThin 
     End With 
    End With 
    xlCol = xlCol + 2 
    g_RS3.MoveNext 
Loop 

一旦實際填充數據到每對列和了解程度，只需使用Range.FillDown method來填充剩下的公式。

我會建議刪除不相關的記錄代碼部分。記錄的代碼非常冗長，妨礙了可讀性。您可能還想查看在T-SQL中創建查詢的For XML方法。這將擴展返回的列，並允許您使用字段計數來確定範圍。