Perl中格式不正確的JSON字符串

Question

我想將json文件轉換爲xml。因此，掃描JSON目錄，並且如果到達那裏的任何文件將被轉換爲xml並移動到xml目錄。

但是我正在此錯誤

的ReadLine（）上閉合的文件句柄$跳頻在json.pl管線29
格式錯誤JSON字符串，既不陣列，對象，數字，字符串或原子，在字符（前 「（字符串的結束）」）在json.pl線34

json.pl

#!/usr/bin/perl 

use strict; 
use warnings; 
use File::Copy; 

binmode STDOUT, ":utf8"; 
use utf8; 

use JSON; 
use XML::Simple; 

# Define input and output directories 
my $indir = 'json'; 
my $outdir = 'xml'; 

# Read input directory 
opendir DIR, $indir or die "Failed to open $indir"; 
my @files = readdir(DIR); 
closedir DIR; 

# Read input file in json format 
for my $file (@files) 
{ 
my $json; 
{ 
    local $/; #Enable 'slurp' mode 
    open my $fh, "<", "$indir/$file"; 
    $json = <$fh>; 
    close $fh; 
} 

# Convert JSON format to perl structures 
my $data = decode_json($json); 

# Output as XML 
open OUTPUT, '>', "$outdir/$file" or die "Can't create filehandle: $!"; 
select OUTPUT; $| = 1; 
print "<?xml version=\"1.0\" encoding=\"UTF-8\" standalone=\"yes\"?>\n"; 
print XMLout($data); 
print "\n" ; 
close(OUTPUT); 
unlink "$indir/$file"; 

} 

example.js偏移0在

{ 
"Manager": 
    { 
     "Name" : "Mike", 
     "Age": 28, 
     "Hobbies": ["Music"] 
    }, 
"employees": 
    [ 
     { 
      "Name" : "Helen", 
      "Age": 26, 
      "Hobbies": ["Movies", "Tennis"] 
      }, 
     { 
      "Name" : "Rich", 
      "Age": 31, 
      "Hobbies": ["Football"] 

     } 
    ] 
} 

Answer 1

你是不是在open檢查錯誤，你是不是跳過目錄條目（readdir將返回.和..條目）。

如果使用

open my $fh, "<", "$indir/$file" or die "$file: $!"; 

你可能會很快發現問題。

「readline（）on closed filehandle $ fh」在說「open $fh失敗，但你仍然繼續前進」。

Answer 2

正如@cjm指出的那樣，問題在於您試圖打開並讀取源目錄中的目錄以及文件。

這是一個解決方案，它也使用autodie來避免不斷檢查所有IO操作的狀態。我也收拾了一些東西。

#!/usr/bin/perl 

use utf8; 
use strict; 
use warnings; 
use autodie; 

use open qw/ :std :encoding(utf8) /; 

use JSON qw/ decode_json /; 
use XML::Simple qw/ XMLout /; 

my ($indir, $outdir) = qw/ json xml /; 

my @indir = do { 
    opendir my $dh, $indir; 
    readdir $dh; 
}; 

for my $file (@indir) { 

    my $infile = "$indir/$file"; 
    next unless -f $infile; 

    my $json = do { 
    open my $fh, '<', $infile; 
    local $/; 
    <$fh>; 
    }; 

    my $data = decode_json($json); 

    my $outfile = "$outdir/$file"; 
    open my $out_fh, '>', "$outdir/$file"; 
    print $out_fh '<?xml version="1.0" encoding="UTF-8" standalone="yes"?>', "\n"; 
    print $out_fh XMLout($data), "\n"; 
    close $out_fh; 

    unlink $infile; 
}