在perl中調度函數，如何包含我們的列表

Question

我發現在perl中分派很多函數的最快方法是使用函數引用。 剩下的問題是，我必須將函數名稱包含在調度程序和函數模塊中的我們的（$ func1，$ func2，...）列表中。我不能以任何方式包含它們，就像C包括會做的那樣。在這裏我的代碼： 主要模塊：

use strict; 
our ($base); 

$base = '/home/en/dtest/perl/forditas/utf8/forditas/test1'; 
require("$base/disph1.pl"); 
require("$base/fut1h1.pl"); 


for (my $j = 0; $j < 5; $j++){ 
    dispatch($j); 
} 

調度模塊：

use strict; 
our ($base); 
require("$base/fut1h1.pl"); 

our ($sref1, $sref2, $sref3, $sref4, $sref5); # This is what I'd like to include 

my %shash = (
    '0' => $sref1, 
    '1' => $sref2, 
    '2' => $sref3, 
    '3' => $sref4, 
    '4' => $sref5, 
); 

sub dispatch($){ 
    my ($ix) = @_; 
    my ($a, $b, $c); 
    $a = 1; $b = 2; $c = 3; 
    my $ref = $shash{$ix}; 
    &$ref($a,$b, $c); 
} 

1; 

功能模塊：

use strict; 

our ($sref1, $sref2, $sref3, $sref4, $sref5); # This is what I'd like to include 

$sref1 = sub($$$) { 
    my ($a,$b,$c) = @_; 
    print "sub1 $a,$b,$c\n"; 
}; 
$sref2 = sub($$$) { my ($a,$b,$c) = @_; print "sub2 $a, $b, $c\n"; }; 
$sref3 = sub { print "sub3\n"; }; 
$sref4 = sub { print "sub4\n"; }; 
$sref5 = sub { print "sub5\n"; }; 

1; 

這是一個運行的結果：

$ perl enhufh1.pl 
sub1 1,2,3 
sub2 1, 2, 3 
sub3 
sub4 
sub5 

在此先感謝提示。

Answer 1

您確實應該使用Perl模塊 - *.pm文件 - 並將它們包括在需要use的地方。使這些模塊的子類Exporter允許它們將變量和子程序名稱導出到調用包中。

看看這三個來源的集合，這也對您的原始代碼添加了一些改進。

注意，你可以用它代替@EXPORT_OK的@EXPORT陣列，在這種情況下，相應use聲明沒有列出要導入的符號。但是，最好在使用點列出符號，否則必須檢查模塊的代碼以準確發現要導入的內容。

main.pl

use strict; 
use warnings; 

use lib '/home/en/dtest/perl/forditas/utf8/forditas/test1'; 

use Dispatcher qw/ dispatch /; 

dispatch($_) for 0 .. 4; 

/家庭/ EN/DTEST/perl的/ forditas/UTF8/forditas/TEST1 /調度。下午

package Dispatcher; 

use strict; 
use warnings; 

require Exporter; 
our @ISA = qw/ Exporter /; 
our @EXPORT_OK = qw/ dispatch /; 

use Utils qw/ sub1 sub2 sub3 sub4 sub5 /; 

my @dtable = (\&sub1, \&sub2, \&sub3, \&sub4, \&sub5); 

sub dispatch { 
    my ($i) = @_; 
    my ($a, $b, $c) = (1, 2, 3); 
    $dtable[$i]($a, $b, $c); 
} 

1; 

/home/en/dtest/perl/forditas/utf8/forditas/test1/Utils.pm

package Utils; 

use strict; 
use warnings; 

require Exporter; 
our @ISA = qw/ Exporter /; 
our @EXPORT_OK = qw/ sub1 sub2 sub3 sub4 sub5 /; 

sub sub1 { 
    my ($a, $b, $c) = @_; 
    print "sub1 $a,$b,$c\n"; 
} 

sub sub2 { 
    my ($a, $b, $c) = @_; 
    print "sub2 $a, $b, $c\n"; 
} 

sub sub3 { 
    print "sub3\n"; 
} 

sub sub4 { 
    print "sub4\n"; 
} 

sub sub5 { 
    print "sub5\n"; 
} 

1; 

輸出

sub1 1,2,3 
sub2 1, 2, 3 
sub3 
sub4 
sub5 

Answer 2

你需要的是Exporter。

在你的模塊：

require Exporter; 

@EXPORT = qw($sref1 $sref2 $sref3); 

但是，它可能是值得考慮不同的設計：

腳本：

set_dispatch(0,sub{ .... }); 

分派器模塊：

my @dispatch; #If just indexing to numbers, use an array instead of a hash. 

sub set_dispatch { 
    $dispatch[$_[0]] = $_[1]; 
} 

主要模塊：

for (0..4) #equivalent to before, but more Perlish. 
{ 
    dispatch($_); 
} 

使用函數調用來設置調度功能比出口一堆的變數，我的腦海裏更好。

Answer 3

• 首先將元素映射爲整數是一種濫用的散列。你也可以使用數組。

• 然後，您似乎想要將算法從實現中分離出來，並將它們加入到主腳本中。雖然這是令人欽佩的，但顯然功能模塊知道它用於什麼。因此，在推導出一種知識圖時，最簡單的情況是你的功能模塊知道這個補丁模塊。

您可以只創建一個輔助函數用於此目的：

use strict; 
use warnings; 

our @EXPORT_OK = qw<setup_dispatch dispatch>; 
use parent 'Exporter'; 

my @dispatch_subs; 
sub setup_dispatch { @dispatch_subs = @_; } 

sub dispatch { 
    my ($a, $b, $c) = (1, 2, 3); 
    return $dispatch_subs[shift()]->($a, $b, $c); 
} 

現在你的功能模塊可以調用設置功能可按：

use strict; 
use warnings; 
use Dispatch(); 

Dispatch::setup_dispatch( 
    # I echo the caution about using prototypes 
    sub ($$$) { 
    my ($a,$b,$c) = @_; 
    print "sub1 $a,$b,$c\n"; 
    } 
, sub ($$$) { my ($a,$b,$c) = @_; print "sub2 $a, $b, $c\n"; } 
, sub { print "sub3\n"; } 
, sub { print "sub4\n"; } 
, sub { print "sub5\n"; } 
); 

而且你只使用這兩者在這樣的主模塊中：

use strict; 
use warnings; 
require 'plugin_functions.pl'; 

use Dispatch qw<dispatch>; 

... 

如果您只是想使用「索引」通用名稱，您確實不需要「名稱」。把它們放在一個列表中。