根據文件數量將文件從文件夾移動到新文件夾

Question

這可能是一個特定情況，但考慮到正確的代碼，我相信很多人都可以從中獲得。

我在一個文件夾中有數千個文件需要分成多個文件夾。每個文件夾需要比之前的文件多一個文件，並且需要按照這種方式命名。每個文件夾至少需要至少有X個文件。例如，下面是最終的結果可能是什麼樣子，如果每個文件夾必須有至少1文件：

U:\Batch\Original\ --> 
    file1.xml 
    file2.xml 
    file3.xml 
    file4.xml 
    file5.xml 
    file6.xml 

U:\Batch\Processed\ --> 
    folder1.1 --> 
     file1.xml 
    folder2.2 --> 
     file2.xml 
     file3.xml 
    folder3.3 --> 
     file4.xml 
     file5.xml 
     file6.xml 

我已經開始attempting this on my own，但我覺得我的路要走。假設我在每個文件夾中至少需要1000個文件。如何在.bat程序中執行此操作？

Answer 1

你在這裏。這應該處理它。

@echo off 
setlocal enabledelayedexpansion 
set /a "minimum=1000, outer=minimum, inner=1" 
set folder_prefix=folder 
call :mkfolder 

:: dir list, order by name, exclude directories, exclude this batch script 
for /f "delims=" %%I in ('dir /b /o:n /a:-d ^| findstr /v "%~nx0"') do (
    if !inner! GTR !outer! (
     set /a "inner=1, outer+=1" 
     call :mkfolder 
    ) 
    copy "%%I" "!folder!" >NUL 
    set /a "inner+=1" 
) 

:: rename final directory to reflect the number of files contained within 
for /f "delims=" %%I in ("%folder%") do set "to=%%~dpnI" 
set /a "inner-=1" 
ren "%folder%" "%to%.%inner%" 


goto :EOF 

:mkfolder 
set folder=%folder_prefix%!outer!.!outer! 
if not exist "!folder!" mkdir "!folder!" 
goto :EOF 

Answer 2

你是在正確的軌道上。爲了演示，首先我們需要創建一些文件一起工作：

md c:\y 
cd /d c:\y 
for %i in (1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30) do echo.>%i.txt 

現在我們可以從c:\y運行批處理文件來創建子文件夾和複製文件，如你表示（但3爲最低在這個例子中的文件）：

@echo off 

setlocal EnableDelayedExpansion 

set cnt=1 
set fldr=1 
set min=3 

for %%i in (*.txt) do (
    if !cnt! GTR !min! (
    set /a cnt-=1 
    ren folder!fldr! folder!fldr!.!cnt! 
    set cnt=1 
    set /a fldr+=1 
    set /a min+=1 
) 

    md folder!fldr! > nul 2>&1 

    copy "%%i" folder!fldr! 

    set /a cnt+=1 
) 

set /a cnt-=1 
ren folder!fldr! folder!fldr!.!cnt!