如何搜索匹配字符串的Perl數組？

Question

什麼是在Perl中搜索匹配字符串的最簡單的方法？

一個警告，我想搜索不區分大小寫

所以"aAa"將是("aaa","bbb")

Answer 1

我猜

@foo = ("aAa", "bbb"); 
@bar = grep(/^aaa/i, @foo); 
print join ",",@bar; 

會做的伎倆。

Answer 2

#!/usr/bin/env perl 

use strict; 
use warnings; 
use Data::Dumper; 

my @bar = qw(aaa bbb); 
my @foo = grep {/aAa/i} @bar; 

print Dumper \@foo; 

Answer 3

這取決於你想要搜索的事：

• ，如果你想找到所有匹配，使用內置grep：

  my @matches = grep { /pattern/ } @list_of_strings; 
  

• 如果你想

  找到第一次匹配，使用first in List::Util：

  use List::Util 'first'; 
  my $match = first { /pattern/ } @list_of_strings; 
  

• ，如果你想找到的所有比賽的計數，使用true在List::MoreUtils：

  use List::MoreUtils 'true'; 
  my $count = true { /pattern/ } @list_of_strings; 
  

• ，如果你想知道指數的第一場比賽的，在List::MoreUtils使用first_index ：

  use List::MoreUtils 'first_index'; 
  my $index = first_index { /pattern/ } @list_of_strings; 
  

• 如果你想簡單地k現在如果有一個匹配，但你不在乎哪個元素它或它的價值，使用any在List::Util：

  use List::Util 1.33 'any'; 
  my $match_found = any { /pattern/ } @list_of_strings; 
  

所有這些例子在他們的核心做類似的事情，但他們的這些實現經過了大量優化，速度很快，並且比使用grep,map或for loop編寫的純perl實現要快。

---

請注意，執行循環的算法是一個單獨的問題，而不是執行單個匹配。要不區分大小寫地匹配一個字符串，您可以簡單地使用i標誌的模式：/pattern/i。如果您之前沒有這樣做，您一定要通讀perldoc perlre。

Answer 4

如果你會做許多搜索數組，和匹配總是被定義爲等價的字符串，那麼你就可以標準化您的數據和使用散列。

my @strings = qw(aAa Bbb cCC DDD eee); 

my %string_lut; 

# Init via slice: 
@string_lut{ map uc, @strings } =(); 

# or use a for loop: 
# for my $string (@strings) { 
#  $string_lut{ uc($string) } = undef; 
# } 


#Look for a string: 

my $search = 'AAa'; 

print "'$string' ", 
    (exists $string_lut{ uc $string ? "IS" : "is NOT"), 
    " in the array\n"; 

讓我強調一下，如果您計劃在數組上進行多次查找，那麼做一個哈希查找是很好的。此外，只有在匹配意味着$foo eq $bar或通過規範化才能滿足其他要求（如不區分大小寫）的情況下，它纔會起作用。

Answer 5

的Perl 5.10+包含「智能匹配」操作符~~，如果某個元素包含在一個數組或哈希返回true，假如果不（見perlfaq4）：

的好處事情是，它也支持正則表達式，這意味着你不區分大小寫的要求可以很容易地照顧：

use strict; 
use warnings; 
use 5.010; 

my @array = qw/aaa bbb/; 
my $wanted = 'aAa'; 

say "'$wanted' matches!" if /$wanted/i ~~ @array; # Prints "'aAa' matches!" 

Answer 6

Perl的字符串匹配，也可用於簡單的是/否。

my @foo=("hello", "world", "foo", "bar"); 

if ("@foo" =~ /\bhello\b/){ 
    print "found"; 
} 
else{ 
    print "not found"; 
} 

Answer 7

對於剛剛一個布爾匹配結果或發生計數，你可以使用：

use 5.014; use strict; use warnings; 
my @foo=('hello', 'world', 'foo', 'bar', 'hello world', 'HeLlo'); 
my $patterns=join(',',@foo); 
for my $str (qw(quux world hello hEllO)) { 
    my $count=map {m/^$str$/i} @foo; 
    if ($count) { 
     print "I found '$str' $count time(s) in '$patterns'\n"; 
    } else { 
     print "I could not find '$str' in the pattern list\n" 
    }; 
} 

輸出：

I could not find 'quux' in the pattern list 
I found 'world' 1 time(s) in 'hello,world,foo,bar,hello world,HeLlo' 
I found 'hello' 2 time(s) in 'hello,world,foo,bar,hello world,HeLlo' 
I found 'hEllO' 2 time(s) in 'hello,world,foo,bar,hello world,HeLlo' 

不要求使用的模塊。
當然，它不像上面的代碼那樣「可擴展」和多功能。
我使用這個交互式用戶答案來匹配預定義的一組不區分大小寫的答案。