找到第一個空白行，當你有多個不同長度的列

Question

我有一個有趣的（希望）爲你們，並提前感謝！

我有一份報告，我正在創建將從其他工作簿中獲取表格並將其複製到默認書籍中的單個報告頁面的報告。

重複此操作直到所有工作簿都被掃描。我使用LastRow和LastPos來維護表單中的位置以免覆蓋，但是我發現有些報表不使用我試圖找到LastRow的列。

因此，做一些像Range("A65536").End(xlup).Select我必須檢查每個報告，看看最長的列是什麼。它可能是A或B或C或D？

我的問題是，有沒有簡單的方法檢查這些值並找到最大的值，以便我可以分配給一個變量並使用？

感謝，

傑夫

Answer 1

我使用這個功能適用於所有的我的 「最後」 的需要：

Function Last(choice As Long, rng As Range) 
'Ron de Bruin, 5 May 2008 
' 1 = last row 
' 2 = last column 
' 3 = last cell 
    Dim lrw As Long 
    Dim lcol As Long 

    Select Case choice 

    Case 1: 
     On Error Resume Next 
     Last = rng.Find(what:="*", _ 
         After:=rng.Cells(1), _ 
         LookAt:=xlPart, _ 
         LookIn:=xlFormulas, _ 
         SearchOrder:=xlByRows, _ 
         SearchDirection:=xlPrevious, _ 
         MatchCase:=False).Row 
     On Error GoTo 0 

    Case 2: 
     On Error Resume Next 
     Last = rng.Find(what:="*", _ 
         After:=rng.Cells(1), _ 
         LookAt:=xlPart, _ 
         LookIn:=xlFormulas, _ 
         SearchOrder:=xlByColumns, _ 
         SearchDirection:=xlPrevious, _ 
         MatchCase:=False).Column 
     On Error GoTo 0 

    Case 3: 
     On Error Resume Next 
     lrw = rng.Find(what:="*", _ 
         After:=rng.Cells(1), _ 
         LookAt:=xlPart, _ 
         LookIn:=xlFormulas, _ 
         SearchOrder:=xlByRows, _ 
         SearchDirection:=xlPrevious, _ 
         MatchCase:=False).Row 
     On Error GoTo 0 

     On Error Resume Next 
     lcol = rng.Find(what:="*", _ 
         After:=rng.Cells(1), _ 
         LookAt:=xlPart, _ 
         LookIn:=xlFormulas, _ 
         SearchOrder:=xlByColumns, _ 
         SearchDirection:=xlPrevious, _ 
         MatchCase:=False).Column 
     On Error GoTo 0 

     On Error Resume Next 
     Last = rng.Parent.Cells(lrw, lcol).Address(False, False) 
     If Err.Number > 0 Then 
      Last = rng.Cells(1).Address(False, False) 
      Err.Clear 
     End If 
     On Error GoTo 0 

    End Select 
End Function 

用法是這樣的：

dim LR as Long 
LR = Last(1,Sheet1.Cells)