for循環中的批處理文件變量

Question

我在繞過批處理文件中的變量時遇到了一些困難。當我認爲我已經失敗了，我發現一個例子，它不工作，因爲我期望，我覺得我一直在這個圈子...

我已經寫了我的整個批量代碼它有所不同，基本上我有一個存檔文件夾與許多子文件夾，我想檢查我的上傳數據（將被移動到存檔文件夾在腳本的末尾 - 當我得到這部分工作要寫）有已經被處理。如果是這樣，移動到Duplicates文件夾與日期：

@echo off 

for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set localDT=%%j 
set localYYYY=%localDT:~0,4% 
set localMM=%localDT:~4,2% 
set localDD=%localDT:~6,2% 
set localDate=%localYYYY%-%localMM%-%localDD% 
set localTime=%localDT:~8,2%:%localDT:~10,2% 

for %%f in ("C:\Test\837Store\*.837") DO if exist /R "C:\Test\Archive\%%~nxf" (
    set VariableTemp=%%~nxf 
    echo %VariableTemp% 
    IF NOT EXIST "C:\Test\Archive\Duplicates" mkdir "C:\Test\Archive\Duplicates" 
    IF NOT EXIST "C:\Test\Archive\Duplicates\%localYYYY%" mkdir "C:\Test\Archive\Duplicates\%localYYYY%" 
    IF NOT EXIST "C:\Test\Archive\Duplicates\%localYYYY%\%localMM%" mkdir "C:\Test\Archive\Duplicates\%localYYYY%\%localMM%" 
    copy "%%~nxf" "C:\Test\Archive\Duplicates\%localYYYY%\%localMM%" 
    echo %localDate% %localTime%  Duplicate claims file: %%~dpnxf File moved to archive  >> "C:\Test\Log\Error.log" 
) 
pause 

我的問題是，變量%% f似乎並沒有通過循環設置。運行mkdir命令，但當我們到達副本時，出現「文件未找到」錯誤。爲了試着看看發生了什麼，我包含了VariableTemp並根據代碼進行了設置，期望看到文件的名稱和擴展名。相反，我的回聲是打印「％〜nxf」

任何人都可以幫我理解這些變量是如何工作的？爲什麼我沒有看到來自我的837Store的文件名？

只是爲了更多的信息，我有以下2個文件在C：\測試\ 837Store：

1.837 2.837

我在C相同的2個文件：\測試\存檔\ 2013 \ 08，所以會期望它們從837Store移動到相關的Duplicates文件夾。

謝謝。

Answer 1

@ECHO OFF 
SETLOCAL 

for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set localDT=%%j 
set localYYYY=%localDT:~0,4% 
set localMM=%localDT:~4,2% 
set localDD=%localDT:~6,2% 
set localDate=%localYYYY%-%localMM%-%localDD% 
set localTime=%localDT:~8,2%:%localDT:~10,2% 

mkdir "U:\Test\Archive\Duplicates\%localYYYY%\%localMM%" 2>nul 


for /R U:\Test\837Store %%f in (*.837) DO ECHO processing %%~ff&if exist "U:\Test\Archive\%%~nxf" (
IF EXIST "u:\Test\Archive\Duplicates\%localYYYY%\%localMM%\%%~nxf" (
    echo %localDate% %localTime%  Duplicate claims file: %%~dpnxf File ALREADY DUPLICATED >> "u:\Error.log" 
) ELSE (
    MOVE "%%~ff" "u:\Test\Archive\Duplicates\%localYYYY%\%localMM%" 
    echo %localDate% %localTime%  Duplicate claims file: %%~dpnxf File moved to archive  >> "u:\Error.log" 
) 
) 
rmdir "U:\Test\Archive\Duplicates\%localYYYY%\%localMM%" 2>nul 
rmdir "U:\Test\Archive\Duplicates\%localYYYY%" 2>nul 
rmdir "U:\Test\Archive\Duplicates" 2>nul 
GOTO :EOF 

這是我的解釋。

我已經使用我的RAMdrive進行測試，所以驅動器號將需要更改，並且還需要錯誤日誌位置。

我已經添加了一個額外的測試重複已存在 - 只是報告這種情況。

我已將您的COPY更改爲MOVE以符合您的敘述。無論採用哪種方式，追加到該命令的>nul都應該禁止'1文件複製/移動'消息，如果您想禁止它。

MD/MKDIR將在目標上方創建任何必需的子目錄。

最後三個'rmdir/RD`的目的是刪除任何空目錄名稱的子目錄。