刪除在Excel 2007

Question

上柱A的空行我有下面的代碼段，在空行需要從列A，然後刪除該整行。我無法使用2010年的Special - > Blanks - > Delete Sheet Rows功能，因爲2007的上界約有80​​00個非連續行。這些代碼在一些較舊的機器上速度非常慢，大約需要40分鐘才能完成（但完成這項工作）。有沒有更快的選擇呢？

Private Sub Del_rows() 
    Dim r1 As Range, xlCalc As Long 
    Dim i As Long, j As Long, arrShts As Variant 
    With Application 
     xlCalc = .Calculation 
     .Calculation = xlCalculationManual 
     .ScreenUpdating = False 
    End With 
    arrShts = VBA.Array("Sheet1") 'add additional sheets as required 
    For i = 0 To UBound(arrShts) 
     With Sheets(arrShts(i)) 
      For j = .UsedRange.Rows.Count To 2 Step -8000 
       If j - 7999 < 2 Then 
        .Range("A2:A" & j).SpecialCells(xlCellTypeBlanks).EntireRow.Delete 
       Else 
        .Range("A" & j, "A" & j - 7999).SpecialCells(xlCellTypeBlanks).EntireRow.Delete 
       End If 
      Next j 
     End With 
    Next i 
    Application.Calculation = xlCalc 

Answer 1

此代碼需要在第二個10萬行（如果需要記錄更爲全面的代碼的動作）：

Sub DeleteRows() 

Application.ScreenUpdating = False 
Columns(1).Insert xlToRight 
Columns(1).FillLeft 
Columns(1).Replace "*", 1 
Cells.Sort Cells(1, 1) 
Columns(1).SpecialCells(xlCellTypeBlanks).EntireRow.Delete 
Columns(1).Delete 

End Sub 

Answer 2

拉吉夫，試試這個。這應該很快。

Option Explicit 

Sub Sample() 
    Dim delrange As Range 
    Dim LastRow As Long, i As Long 

    With Sheets("Sheet1") '<~~ Change this to the relevant sheetname 
     '~~> Get the last Row in Col A 
     LastRow = .Range("A" & .Rows.Count).End(xlUp).Row 

     For i = 1 To LastRow 
      If Len(Trim(.Range("A" & i).Value)) = 0 Then 
       If delrange Is Nothing Then 
        Set delrange = .Rows(i) 
       Else 
        Set delrange = Union(delrange, .Rows(i)) 
       End If 
      End If 
     Next i 

     If Not delrange Is Nothing Then delrange.Delete 
    End With 
End Sub 

編輯：

您還可以使用自動篩選刪除行。這很快。我還沒有測試這兩個巨大的行的例子:)請讓我知道，如果你有任何錯誤。

Option Explicit 

Sub Sample() 
    Dim lastrow As Long 
    Dim Rng As Range 

    With Sheets("Sheet1") 
     lastrow = .Range("A" & .Rows.Count).End(xlUp).Row 

     '~~> Remove any filters 
     .AutoFilterMode = False 

     With .Range("A1:A" & lastrow) 
      .AutoFilter Field:=1, Criteria1:="" 
      .Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete 
     End With 

     '~~> Remove any filters 
     ActiveSheet.AutoFilterMode = False 
    End With 
End Sub 

HTH

希德