它有一個簡單的方法來洗牌AppleScript中的列表？

Question

它有一個簡單的方法來洗牌AppleScript中的列表？

我已經做了幾次搜索，並畫出了一個空白。

Answer 1

較短版本的費雪耶茨算法：

on shuffle(l) 
    set i to count of l 
    repeat while i ≥ 2 
     set j to random number from 1 to i 
     tell l to set {item i, item j} to {item j, item i} 
     set i to i - 1 
    end repeat 
    l 
end shuffle 

set l to {} 
repeat 1000 times 
    set end of l to random number from 1 to 1000 
end repeat 
shuffle(l) 

有我* ...... * 2 =我！可能的隨機數字序列。它們全部對應於我的一個排列！列表的排列。

一個使用腳本對象的更快版本：

on shuffle(input) 
    script s 
     property l : input 
    end script 
    set i to count of l of s 
    repeat while i ≥ 2 
     set j to random number from 1 to i 
     set {item i of l of s, item j of l of s} to {item j of l of s, item i of l of s} 
     set i to i - 1 
    end repeat 
    l of s 
end shuffle 

腳本歷時約：

• 0.15和0.06秒1000個元素
• 12和0.5秒10000個元件
• 對於100000個元素，976秒和4秒

所以第一個腳本具有指數時間複雜性。 regulus發佈的腳本稍微慢一些。

當我將第一個腳本保存爲scpt並將10000個元素添加到列表中時，我遇到了limit for the number of items that can be saved in a compiled script。

Answer 2

我想我已經破解了它。包裹在一個易於使用的功能。

set myList to {1, 2, 3, 4, 5, 6, 7, 8, 9, 10} 

set answer to listShuffle(myList) 


on listShuffle(theList) 

set listLength to count of theList 

repeat while listLength > 1 



    set r to random number from 1 to listLength 

    set item1 to item listLength of theList 
    set item2 to item r of theList 

    set item listLength of theList to item2 
    set item r of theList to item1 

    set listLength to listLength - 1 

end repeat 

return theList 

end listShuffle 

Answer 3

這是另一種選擇。而不是「洗牌」列表中，我們只是隨機從列表中搶項目，並把它們插入到一個新的列表...

set myList to {1, 2, 3, 4, 5, 6, 7, 8, 9, 10} 
set randomizedList to randomizeList(myList) 

on randomizeList(theList) 
    set listCount to count of theList 

    set newList to {} 
    repeat listCount times 
     set subListCount to count of theList 
     set r to random number from 1 to subListCount 
     set end of newList to item r of theList 

     -- remove the random item from theList 
     if subListCount is 1 then 
      exit repeat 
     else if r = 1 then --> first item 
      set theList to items 2 thru end of theList 
     else if r = subListCount then --> last item 
      set theList to items 1 thru -2 of theList 
     else 
      set theList to items 1 thru (r - 1) of theList & items (r + 1) thru -1 of theList 
     end if 
    end repeat 

    return newList 
end randomizeList 

編輯：如果你想加快的大名單上的行動你可以使用腳本對象。當名單很大時，你會經常看到很大的速度增益。所以，你可以寫你使用腳本對象這樣的代碼......

set myList to {1, 2, 3, 4, 5, 6, 7, 8, 9, 10} 
set answer to listShuffle(myList) 

on listShuffle(theList) 
    script s 
     property l : missing value 
    end script 
    set s's l to theList 

    set listLength to count of s's l 

    repeat while listLength > 1 
     set r to random number from 1 to listLength 

     set item1 to item listLength of s's l 
     set item2 to item r of s's l 

     set item listLength of s's l to item2 
     set item r of s's l to item1 

     set listLength to listLength - 1 
    end repeat 

    return s's l 
end listShuffle 

Answer 4

如果在新列表中的項目不必是唯一的，那麼你可以用非常有效的

set selectedItemVar to some item of list someItemListVar 

Answer 5

我只是拋出我的解決方案。我個人只使用非常短的名單（約200項），從中我需要提取各種長度的獨特隨機子列表。將該算法應用於整個列表（即傳入count of mainList,maxCount）將導致原始列表的混洗版本。這不是爲了速度而構建的，但對於算法不強的人可能更容易獲得。

on randomizedSublist(mainList, maxCount) 
    set sublist to {} as list 
    repeat with x from 1 to maxCount 
     set oneItem to some item of mainList 
     repeat until sublist does not contain oneItem 
      set oneItem to some item of mainList 
     end repeat 
     set end of sublist to oneItem 
    end repeat 
    return sublist 
end randomizedSublist