如何在不同的串行器之間共享Dancer2應用程序之間的會話數據？

Question

我正在嘗試將一個應用程序從Dancer遷移到Dancer2。我的想法是將代碼分離爲使用模板和Ajax（API）調用的路由。

我的基本程序是：

use strict; 
use warnings; 
use FindBin; 
use Plack::Builder; 

use Routes::Templates; 
use Routes::Login; 

builder { 
    mount '/' => Routes::Templates->to_app; 
    mount '/api' => Routes::Login->to_app; 
}; 

我在想，在Routes::Templates包不會有任何串行和Routes::Login包將有JSON序列化。我用

set serializer => 'JSON'; 

在Routes::Login包。

不過，我也希望這些共享會話數據，使每個人都有每個文件中常見的應用程序的名字

use Dancer2 appname => 'myapp'; 

。這似乎與串行化遇到麻煩。 Routes::Template路由未正確返回，因爲它試圖將其編碼爲JSON。這裏的錯誤：

Failed to serialize content: hash- or arrayref expected (not a simple scalar, use allow_nonref to allow this)

我讀過的所有文件，其中包括：

• How can I use Dancer2::Plugin::Database when my code is split into multiple files?
• https://github.com/wyoung/advent-calendar/tree/master/danceradvent/public/articles/2015

但我仍然沒有就如何串行明確被包分開。

Answer 1

有沒有必要結合您的應用程序使用appname;只要兩個應用程序對會話引擎使用相同的配置，會話數據就會共享。 （另外，在serializers are an all-or-nothing prospect Dancer2，讓您真正有使用兩個單獨的應用程序）

下面是我給的dancer-users mailing list的例子：

MyApp的/ lib目錄/ MyApp.pm

package MyApp; 
use Dancer2; 

our $VERSION = '0.1'; 

get '/' => sub { 
    session foo => 'bar'; 
    template 'index'; 
}; 

true; 

MyApp的/ LIB/MyApp的/ API.pm

package MyApp::API; 
use Dancer2; 

set serializer => 'JSON'; 

get '/' => sub { 
    my $foo = session('foo') // 'fail'; 
    return { foo => $foo }; 
}; 

true; 

MyApp的/ bin中/ app.psgi

#!/usr/bin/env perl 

use strict; 
use warnings; 
use FindBin; 
use lib "$FindBin::Bin/../lib"; 

use MyApp; 
use MyApp::API; 
use Plack::Builder; 

builder { 
    mount '/' => MyApp->to_app; 
    mount '/api' => MyApp::API->to_app; 
}; 

如果您訪問/路線，然後在同一瀏覽器的/api路線，你會得到

{"foo":"bar"} 

表明同一個會話兩個請求都使用了變量。