複印份數和寫入文件的txt

Question

我有一個VBScript：

Dim Stuff, myFSO, WriteStuff, dateStamp 

Stuff = "Whatever you want written" 

Set myFSO = CreateObject("Scripting.FileSystemObject") 
Set WriteStuff = myFSO.OpenTextFile("C:\Label_1\yourtextfile.txt", 8, True) 
WriteStuff.WriteLine(var1) 
WriteStuff.Close 
SET WriteStuff = NOTHING 
SET myFSO = NOTHING 

其被放置在動作中的關鍵。 在變量「var1」被讀取的條形碼讀取器中，條形碼EAN13以及按下文本文件「C：\ Label_1 \ yourtextfile.txt」 的鍵後被寫入具有值「var1」的新行，即。條碼

2914750018247 

再然後，當我們將掃描條碼

2914750007463 

，並按下按鈕 也將被保存在一個文本文件。

拍攝將是這樣的：

2914750018247 
2914750007463 

當然，掃描的文件 「C：\ Label_1 \ yourtextfile.txt」 會更多，例如。 70個不同的代碼，但總是EAN13。

你怎麼能使用VBScript複製或分發，即5個字符：在文件「C：\ Label_1 \ yourtextfile.txt」

01824 
00746 
... 

與先前存儲的所有值（每5個字符），但他們都當代碼（每個五個字符）將只有70行時，加起來並保存一個新文件txt？

Answer 1

看看下面的例子中，它處理源文件的線和切割每行子：

sSrc = "C:\Users\DELL\Desktop\barcode.txt" 
sDst = "C:\Users\DELL\Desktop\barcode_part.txt" 

' Read content of the source file 
sCont = ReadTextFile(sSrc, 0) ' ASCII 
' Split source file string into array of lines 
aLines = Split(sCont, vbCrLf) 
' Loop through each of the lines in array 
For i = 0 To UBound(aLines) 
    ' Change the value of the element to cut substring 
    aLines(i) = Mid(aLines(i), 8, 5) 
Next 
' Join processed array into resulting string with line breaks 
sCont = Join(aLines, vbCrLf) 
' Write content to the destination file 
WriteTextFile sCont, sDst, 0 ' ASCII 

Function ReadTextFile(sPath, lFormat) 
    ' lFormat -2 - System default, -1 - Unicode, 0 - ASCII 
    With CreateObject("Scripting.FileSystemObject").OpenTextFile(sPath, 1, False, lFormat) 
     ReadTextFile = "" 
     If Not .AtEndOfStream Then ReadTextFile = .ReadAll 
     .Close 
    End With 
End Function 

Sub WriteTextFile(sContent, sPath, lFormat) 
    ' lFormat -2 - System default, -1 - Unicode, 0 - ASCII 
    With CreateObject("Scripting.FileSystemObject").OpenTextFile(sPath, 2, True, lFormat) 
     .Write sContent 
     .Close 
    End With 
End Sub