ColdFusion，REGEX - 鑑於TEXT，查找SPAN中包含的所有項目

Question

我期待學習如何在Coldfusion中創建REGEX，它將掃描大量HTML文本並創建項目列表。

我想要的物品都包含以下

<span class="findme">The Goods</span> 

感謝之間的任何提示，以幫助這是怎麼回事。

Answer 1

你不說什麼版本的CF.由於V8可以使用REMatch獲取數組

results = REMatch('(?i)<span[^>]+class="findme"[^>]*>(.+?)</span>', text) 

使用ArrayToList來把它轉換成一個列表。 對於較早的版本，使用REFindNoCase並使用Mid（）提取子字符串。

編輯：要回答你的後續評論使用REFINDER返回所有匹配的過程是相當涉及，因爲該功能只返回第一場比賽。這意味着您實際上每次都必須多次調用REFIN並傳遞新的startpos。本福塔已經寫了一個UDF，完成這個並且會爲你節省一些時間。

<!--- 
Returns all the matches of a regular expression within a string. 
NOTE: Updated to allow subexpression selection (rather than whole match) 

@param regex  Regular expression. (Required) 
@param text  String to search. (Required) 
@param subexnum Sub-expression to extract (Optional) 
@return Returns a structure. 
@author Ben Forta (ben@forta.com) 
@version 1, July 15, 2005 
---> 
<cffunction name="reFindAll" output="true" returnType="struct"> 
<cfargument name="regex" type="string" required="yes"> 
<cfargument name="text" type="string" required="yes"> 
<cfargument name="subexnum" type="numeric" default="1"> 

<!--- Define local variables --->  
<cfset var results=structNew()> 
<cfset var pos=1> 
<cfset var subex=""> 
<cfset var done=false> 

<!--- Initialize results structure ---> 
<cfset results.len=arraynew(1)> 
<cfset results.pos=arraynew(1)> 

<!--- Loop through text ---> 
<cfloop condition="not done"> 

    <!--- Perform search ---> 
    <cfset subex=reFind(arguments.regex, arguments.text, pos, true)> 
    <!--- Anything matched? ---> 
    <cfif subex.len[1] is 0> 
     <!--- Nothing found, outta here ---> 
     <cfset done=true> 
    <cfelse> 
     <!--- Got one, add to arrays ---> 
     <cfset arrayappend(results.len, subex.len[arguments.subexnum])> 
     <cfset arrayappend(results.pos, subex.pos[arguments.subexnum])> 
     <!--- Reposition start point ---> 
     <cfset pos=subex.pos[1]+subex.len[1]> 
    </cfif> 
</cfloop> 

<!--- If no matches, add 0 to both arrays ---> 
<cfif arraylen(results.len) is 0> 
    <cfset arrayappend(results.len, 0)> 
    <cfset arrayappend(results.pos, 0)> 
</cfif> 

<!--- and return results ---> 
<cfreturn results> 
</cffunction> 

這給了你每場比賽的開始（POS）和長度，從而得到各子使用另一個循環

<cfset text = '<span class="findme">The Goods</span><span class="findme">More Goods</span>' /> 
<cfset pattern = '(?i)<span[^>]+class="findme"[^>]*>(.+?)</span>' /> 
<cfset results = reFindAll(pattern, text, 2) /> 
<cfloop index="i" from="1" to="#ArrayLen(results.pos)#"> 
    <cfoutput>match #i#: #Mid(text, results.pos[i], results.len[i])#<br></cfoutput> 
</cfloop> 

編輯：更新reFindAll與subexnum說法。將其設置爲2將捕獲第一個子表達式。默認值1捕獲整個匹配。

Answer 2

試着尋找使你的HTML使用常規DOM解析器工作並通過XPath查詢的可能性，而不是敲打這個基於正則表達式的可憎的槽。

1. 使HTML輸入可用，使其通過jTidy（見http://jtidy.riaforge.org/）
2. 一旦有了良好的XML/XHTML，使用從它
   <cfset dom = XmlParse(scrubbedHtml, true)>
3. 查詢XML文檔建立的XML文檔XPath
   <cfset result = XmlSearch(dom, "//span[@class='findme']")>

完成。

編輯：Coldfusion的XmlSearch()沒有很好的XML名稱空間支持。如果最終生成的是XHTML而不是更值得推薦的XML，請使用以下XPath（注意冒號）"//:span[@class='findme']"或"//*:span[@class='findme']"。有關更多信息，請參閱here和here。

查看jTidy API documentation瞭解jTidy可以做什麼的完整概述。