當輸出爲空時，它將自動過濾器失敗（當輸出爲空時它將全部顯示）

Question

我正在使用以下代碼進行自動過濾。它的工作正常。問題是如果輸出值清空過濾器給出的所有值。我在尋找是否空出它將顯示空行。

Sub filter() 
     Application.ScreenUpdating = False 
     Dim Location As String 
     Dim due As String 
     Sheets("sheet2").Activate 
     due = Range("b14").Value 
     Location = Range("a14").Value 
     Range("a16:j1000").ClearContents 
     Sheets("Sheet1").Select 
     Range("a1:j1000").Select 
     Selection.AutoFilter 
     ActiveSheet.Range("$A$1:$j$1000").AutoFilter Field:=1, Criteria1:=due 
     ActiveSheet.Range("$A$1:$j$1000").AutoFilter Field:=2, Criteria1:=Location 
     Range("c2:i1000").Select 
     Selection.Copy 
     Sheets("sheet2").Activate 
     Range("b16").Select 
     Selection.PasteSpecial 
     Sheets("sheet1").Select 
     Selection.AutoFilter 
     Sheets("sheet2").Select 
     Range("b16").Activate 
     Application.ScreenUpdating = True 
    End Sub 

Answer 1

當過濾器顯示無結果時，複製過濾列表中的所有數據是已知錯誤。通常，我使用Application.Subtotal(103, ...)（SUBTOTAL Function）在對已過濾列表執行任何操作之前檢查可見記錄。

Sub filter() 
    Application.ScreenUpdating = False 
    Dim Location As String, due As String 

    With Sheets("sheet2") 
     due = .Range("b14").Value 
     Location = .Range("a14").Value 
     .Range("a16:j1000").ClearContents 
    End With 

    With Sheets("sheet1").Range("a1:j1000") 
     .AutoFilter 
     .AutoFilter Field:=1, Criteria1:=due 
     .AutoFilter Field:=2, Criteria1:=Location 
     With .Offset(1, 2).resize(.rows.count - 1, 7) 
      If CBool(Application.Subtotal(103, .Cells)) Then _ 
       .Copy Destination:=Sheets("sheet2").Range("b16") 
     End With 
     .AutoFilter 
    End With 

    With Sheets("sheet2") 
     .Activate 
     Range("b16").Activate 
    End With 
    Application.ScreenUpdating = True 
End Sub 

我已經在樣本數據上成功測試了這個。比較日期時，請小心使用字符串（例如截止日期爲）。

當使用VBA過濾列表並隨後刪除可見記錄時，這一點尤其重要，因爲沒有可見記錄會導致您的整個數據矩陣被刪除。此外，從宏運行時不存在UnDo。