隱藏一個VB.Net後重新排列面板

Question

我創建了一個非常複雜的Windows窗體應用程序。我現在想要做的是，如果點擊不同的按鈕來禁用某些面板，但將其下面的所有其他面板轉移，以便它看起來順序。我對此感到非常難過。我想開發一個函數，它在一個被禁用的面板中傳遞，並在其下面的所有其他面板列表中使用遞歸重新排列所有面板。此功能可以工作，但不考慮如果一個面板的高度大於另一個面板的高度，則會在兩個面板之間留下額外的空間。任何幫助將非常感激。

Public Sub whatever(ByVal panel As Panel, ByVal list As List(Of Panel)) 
    Dim temppanel As Panel = New Panel() 
    For Each item As Panel In list 
     temppanel.Location = New Point(temppanel.Location.X, item.Location.Y) 
     item.Location = New Point(item.Location.X, panel.Location.Y) 
     list.Remove(item) 
     whatever(temppanel, list) 
     If list.Count = 0 Then 
      Exit For 
     End If 
    Next 
End Sub 

圖片

http://imageshack.us/photo/my-images/268/panelsz.png/

Answer 1

一個FlowLayoutPanel的可能是更適合於這一點，但這裏是做什麼，我覺得你的一般方法是尋找：

Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) _ 
          Handles Button1.Click 
    ToggelPanel(Panel2) 
End Sub 

Private Sub ToggelPanel(ByVal whichPanel As Panel) 
    Dim startPoint As New Point(10, 10) 
    whichPanel.Visible = Not whichPanel.Visible 

    For Each pnl As Panel In Me.Controls.OfType(Of Panel)(). _ 
          Where(Function(x) x.Visible). _ 
          OrderBy(Function(x) x.TabIndex) 
    pnl.Location = startPoint 
    startPoint.Y += pnl.Height + 4 
    Next 
End Sub 

將Me替換爲父容器，如果這些面板不在Me。

---

如果使用.NET 2.0，其中LINQ是不可用的，功能會是這個樣子：

Private Shared Function CompareTabIndex(ByVal p1 As Panel, ByVal p2 As Panel) _ 
             As Integer 
    Return p1.TabIndex.CompareTo(p2.TabIndex) 
End Function 

Private Sub ToggelPanel(ByVal whichPanel As Panel) 
    Dim startPoint As New Point(10, 10) 
    whichPanel.Visible = Not whichPanel.Visible 

    Dim panels As New List(Of Panel) 
    For i As Integer = 0 To Me.Controls.Count - 1 
    If TypeOf Me.Controls(i) Is Panel Then 
     If Me.Controls(i).Visible Then 
     panels.Add(Me.Controls(i)) 
     End If 
    End If 
    Next 

    panels.Sort(New Comparison(Of Panel)(AddressOf CompareTabIndex)) 

    For Each pnl As Panel In panels 
    pnl.Location = startPoint 
    startPoint.Y += pnl.Height + pnl.Margin.Bottom 
    Next 
End Sub