如何比較字符串與Xpath 1.0？

Question

我在Xpath 1.0中的字符串上遇到<運算符問題。

這個簡單的XPath表達式

'A' < 'B' (or the equivalent 'A' &lt; 'B') 

沒有評估爲真，在我的libxslt XSLT運行（這是一個XSLT 1.0引擎）。

我檢查了XML Spy，它允許在1.0和2.0中測試Xpath表達式，當然，在Xpath 2.0中它的計算結果爲true，但在Xpath 1.0中它的計算結果爲false！

這是Xpath 1.0中的錯誤嗎？

我應該用什麼其他表達式來比較兩個字符串/字符的字母順序？請注意，compare（）函數不會執行，因爲這是一個XSLT 2.0函數。

Answer 1

是的，這是XPath 1.0的限制。 （我認爲將你不喜歡的限制稱爲「bug」是不合理的，儘管XPath 2.0的設計者明確同意這是一個不受歡迎的限制）。

您已經標記問題「XSLT」，所以你可能能夠解決此問題在XSLT水平，至少如果您的處理器具有節點集擴展：

<xsl:variable name="nodes"> 
    <node><xsl:value-of select="$A"/></node> 
    <node><xsl:value-of select="$B"/></node> 
</xsl:variable> 

<xsl:for-each select="exslt:node-set($nodes)/*"> 
    <xsl:sort select="."/> 
    <xsl:if test="position()=1 and .=$A">A comes first!</xsl:if> 
</xsl:for-each> 

但也許現在是時候轉移到2.0。什麼阻止你回來？

Answer 2

這可能是難看的解決方案，在許多情況下不可行，但對於簡單的字母順序比較，您可以使用translate。下面的代碼片斷只是一個可以furtherly擴展的例子：

translate('A','ABCD','1234') < translate('B','ABCD','1234'); 

您的翻譯表達應涵蓋所有的信件，並低的情況下，並且可以通過定義命名模板可以方便地重複使用。

Answer 3

在XPath 1.0中，只對=和!=定義了字符串比較，並且不提供排序比較。該規範表示

當待比較既不對象是一個節點集合和操作員是 < =，<，> =或>，則目的是通過既 對象轉換爲數字和比較所述比較根據IEEE 754.

因此，您的操作數都被轉換爲浮點數，使它們都是NaN。

我相信微軟的XML增加了擴展功能來處理這個問題，當然這隻有在你使用MSXML的時候纔有用。

Answer 4

爲了證明這對其他人也有用，下面是我根據邁克爾凱的建議寫的代碼。我寫了一個自定義的compare函數，它提供了與Xpath 2.0相同的結果。我還爲該問題添加了php標籤，以便更頻繁地找到它。

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:func="http://exslt.org/functions" 
    xmlns:common="http://exslt.org/common" 
    xmlns:custom="urn:myCustomFunctions" 
    exclude-result-prefixes="func common custom" 
    extension-element-prefixes="func custom"> 

    <xsl:output method="xml"/> 

    <func:function name="custom:compare"> 
     <xsl:param name="string1"/> 
     <xsl:param name="string2"/> 

     <func:result> 
      <xsl:choose> 
       <xsl:when test="$string1 = $string2">0</xsl:when> 
       <xsl:otherwise> 
        <xsl:variable name="nodes"> 
         <node><xsl:value-of select="$string1"/></node> 
         <node><xsl:value-of select="$string2"/></node> 
        </xsl:variable> 
        <xsl:for-each select="common:node-set($nodes)/*"> 
         <xsl:sort select="."/> 
         <xsl:choose> 
          <xsl:when test="position()=1 and .=$string1">-1</xsl:when> 
          <xsl:when test="position()=1 and .=$string2">1</xsl:when> 
         </xsl:choose> 
        </xsl:for-each> 
       </xsl:otherwise> 
      </xsl:choose> 
     </func:result> 
    </func:function> 

    <xsl:template match="/"> 
     <out> 
      <test1><xsl:value-of select="custom:compare('A', 'B')"/></test1> 
      <test2><xsl:value-of select="custom:compare('A', 'A')"/></test2> 
      <test3><xsl:value-of select="custom:compare('C', 'B')"/></test3> 
      <test4><xsl:value-of select="custom:compare('DD', 'A')"/></test4> 
     </out> 
    </xsl:template> 

</xsl:stylesheet> 

運行這個（與虛擬輸入）的結果是

<?xml version="1.0"?> 
<out> 
    <test1>-1</test1> 
    <test2>0</test2> 
    <test3>1</test3> 
    <test4>1</test4> 
</out> 

對於那些誰願意來測試這個在PHP自己，這是我使用的代碼：

<?php 
$xslt = new XSLTProcessor(); 
$xslt->importStylesheet(DOMDocument::load('testCompare.xslt')); 
$xslt -> registerPHPFunctions(); 
$xml = new SimpleXMLElement('<test/>'); 
print $xslt->transformToXML($xml); 
?>