使用SAS數據導出文件時缺失列名步驟

Question

我有一個大的SAS數據集raw_data，其中包含從各個國家收集的數據。該數據集有一個「國家」列，列出了觀察起源的國家。我想在raw_data中爲每個國家導出一個單獨的.csv文件。我用下面的數據步驟產生輸出：

data _null_; 
    set raw_data; 
    length fv $ 200; 
    fv = "/directory/" || strip(put(country,$32.)) || ".csv"; 
    file write filevar=fv dsd dlm=','; 
    put (_all_) (:); 
run; 

然而，生成的.csv文件將不再從raw_data有列名。我的數據集有超過一百列，因此列出所有列名稱是禁止的。任何人都可以提供一些關於如何修改上述代碼的指導，以便將列名添加到正在導出的.csv文件中？任何幫助表示讚賞！

Answer 1

您可以創建一個宏變量來保存變量名稱並將它們放到CSV文件中。

proc sql noprint; 
select name into :var_list separated by ", " 
from sashelp.vcolumn 
where libname="WORK" and memname='RAW_DATA' 
order by varnum; 
quit; 

data _null_; 
set raw_data; 
length fv $ 200; 
by country; 
fv = "/directory/" || strip(put(country,$32.)) || ".csv"; 

if first.country then do; 
    put "&var_list"; 
end; 

file write filevar=fv dsd dlm=','; 
put (_all_) (:); 
run; 

Answer 2

考慮這個數據步驟與您的程序非常相似。它使用VNEXT查詢PDV並將變量名稱寫爲每個文件的第一條記錄。

proc sort data=sashelp.class out=class; 
    by age; 
    run; 
data _null_; 
    set class; 
    by age; 
    filevar=catx('\','C:\Users\name\Documents',catx('.',age,'csv')); 
    file dummy filevar=filevar ls=256 dsd; 
    if first.age then link names; 
    put (_all_)(:); 
    return; 
names: 
    length _name_ $32; 
    call missing(_name_); 
    do while(1); 
     call vnext(_name_); 
    if _name_ eq: 'FIRST.' then leave; 
     put _name_ @; 
    end; 
    put; 
    run;