LWP :: UserAgent設置請求的URL的IP，以便LWP不必做DNS查找

Question

我使用LWP::UserAgent來請求大量的頁面內容。我已經知道我請求的網址的IP地址，所以我希望能夠指定我請求的網址的IP地址，以便LWP不必花時間進行DNS查找。我瀏覽過文檔，但沒有找到任何解決方案。有誰知道一種方法來做到這一點？謝謝！

Answer 1

所以我發現，正是我要找的不模塊：LWP::UserAgent::DNS::Hosts

這裏是我測試和做什麼，我在我的問題指定的一個示例腳本：

#!/usr/bin/perl 
use strict; 
use LWP::UserAgent; 
use LWP::UserAgent::DNS::Hosts; 

LWP::UserAgent::DNS::Hosts->register_host(
     'www.cpan.org' => '199.15.176.140', 
); 

my $ua = LWP::UserAgent->new; 
$ua->timeout(10); 
$ua->env_proxy; 

#actually enforces new DNS settings as if they were in /etc/hosts 
LWP::UserAgent::DNS::Hosts->enable_override; 

my $response = $ua->get('http://www.cpan.org/'); 

if ($response->is_success) { 
    print $response->decoded_content; # or whatever 
} 
else { 
    die $response->status_line; 
} 

Answer 2

只需在您的網址的IP地址替換域名：

use strict; 
require LWP::UserAgent; 

my $ua = LWP::UserAgent->new; 
$ua->timeout(10); 
$ua->env_proxy; 

# my $response = $ua->get('http://stackoverflow.com/'); 
my $response = $ua->get('http://64.34.119.12/'); 

if ($response->is_success) { 
    print $response->decoded_content; # or whatever 
} 
else { 
    die $response->status_line; 
} 

Answer 3

哼，你的系統應該已經被緩存DNS響應。你確定這個優化會有幫助嗎？

---

選項1.

使用

http://192.0.43.10/ 

，而不是

http://www.example.org/ 

當然，如果服務器不基於域名的虛擬主機，將失敗。

---

選項2

替換Socket::inet_aton（從IO稱爲::插座:: INET從LWP ::協議:: HTTP調用）與高速緩存版本。

use Socket qw(); 
BEGIN { 
    my $original = \&Socket::inet_aton; 

    my %cache; 
    my $caching = sub { 
     return $cache{$_[0]} //= $original->($_[0]); 
    }; 

    no warnings 'redefine'; 
    *Socket::inet_aton = $caching; 
}