在oracle APEX郵件正文中選擇和顯示錶格

Question

發送郵件時可以在classic report郵件正文中選擇並顯示數據庫表格？

版本：的Oracle APEX 4.2

樣品：SAMPLE FORMAT FOR EMAIL

問候， DOC

Answer 1

是的，你可以通過發送HTML電子郵件 - 但你必須自己構建HTML 。例如：

declare 
    l_body_text long; 
    l_body_html long; 
begin 
    l_body_html := '<table style="border-collapse: collapse; border: 1px solid black"><tbody>' 
        || '<tr>' 
        || '<th style="background-color: #eef; border: 1px solid black">ENAME</th>' 
        || '<th style="background-color: #eef; border: 1px solid black">DNAME</th></tr>'; 

    for r in (select ename, dname from emp) 
    loop 
     l_body_html := l_body_html || '<tr><td style="border: 1px solid black">' 
        || r.ename || '</td><td style="border: 1px solid black">' 
        || r.dname|| '</td></tr>'; 
    end loop; 
    l_body_html := l_body_html || '</tbody></table>'; 

    l_body_text := 'Plain text version'; 

    apex_mail.send 
     (p_to  => 'you@there.com' 
     , p_from  => 'me@here.com' 
     , p_body  => l_body_text 
     , p_body_html => l_body_html 
     , p_subj  => 'Your report' 
    ); 
end; 

注：

1. 您需要的情況下提供一個純文本替代收件人無法接收HTML格式的電子郵件。
2. 您需要內嵌任何樣式 - 不能引用CSS文件。