XSLT使用默認命名空間轉換XML而不添加前綴？

Question

我想用以下命名空間轉換一個XML文件，但找不到一種方法使它與默認名稱空間一起工作，而不向輸出XML添加前綴。

原始XML文件：

<pExport xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns="http://workflow.converga.com.au/compass"> 

我可以把它添加前綴到默認命名空間的工作（最後一個），但我怎麼可能輸出不添加前綴的XML，可以通過在.NET 4中使用XslCompiledTransform？

Answer 1

我可以把它加入了 前綴默認命名空間（該 最後一個）的工作，但我怎麼會輸出一個 XML沒有添加前綴，它是 可以通過使用XslCompiledTransform 。 NET 4？

這裏是一個具體的例子，如何做到這一點：

這種轉變：

<xsl:stylesheet version="1.0" 
xmlns="http://workflow.converga.com.au/compass" 
xmlns:c="http://workflow.converga.com.au/compass" 
xmlns:ext="http://exslt.org/common" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
exclude-result-prefixes="c ext xsl"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:param name="pnewItem"> 
    <item name="wine"> 
    <price>3</price> 
    <quantity>5000</quantity> 
    </item> 
</xsl:param> 

<xsl:template match="node()|@*" name="identity"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="c:item[last()]"> 
    <xsl:call-template name="identity"/> 
    <xsl:copy-of select="ext:node-set($pnewItem)/*"/> 
</xsl:template> 
</xsl:stylesheet> 

當XslCompiledTransform以下XML文檔應用：

<pExport xmlns="http://workflow.converga.com.au/compass"> 
<Goods> 
    <item name="tobacco"> 
    <price>5</price> 
    <quantity>1000</quantity> 
    </item> 
</Goods> 
</pExport> 

產生想（同一個XML文檔添加了一個新的項目），正確的結果：

<pExport xmlns="http://workflow.converga.com.au/compass"> 
    <Goods> 
    <item name="tobacco"> 
     <price>5</price> 
     <quantity>1000</quantity> 
    </item> 
    <item name="wine"> 
     <price>3</price> 
     <quantity>5000</quantity> 
    </item> 
    </Goods> 
</pExport> 

Answer 2

您只需在XSLT中定義默認命名空間即可。如果你還用一個前綴定義之一，也是這樣你就可以選擇輕鬆輸入XML項目：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://workflow.converga.com.au/compass" xmlns:compass="http://workflow.converga.com.au/compass"> 
    <xsl:template match="compass:pExport"> 
    <pExport>...</pExport> 
    ... 

上面的模板會匹配對您輸入的XML元素 - 和創造的文字元素將在默認輸出命名空間（這是相同的命名空間）。

當然，你應該知道，在XML前綴是無關緊要的 - 兩個項目是相同的，如果它們具有相同的命名空間和本地名稱，即使兩個前綴爲一個命名空間中定義。

<element xmlns="http://test.com"></element> 
<ns01:element xmlns:ns01="http://test.com"></ns01:element> 

上述兩個元素是相同的，因爲它們具有相同的完全限定名稱。

Answer 3

的關鍵是使用exclude-result-prefixes屬性stylesheet元素。

XSLT FAQ的this section有一些很好的解釋。