如何創建一個目標快捷方式將應用程序鏈接到正確的程序 - Inno Setup？

Question

我需要IDL虛擬機添加到我的目標位置爲我的IDL文件名爲.sav我使用Inno Setup的， 而下面的代碼行

[Icons] 
Name: "{group}\clas"; Filename: "{code:GetIDLPath}"; Parameters: """{app}\bin\BATCH_CLAS_MAIN.sav"""; IconFilename: "{app}\clas_icon.ico" 

[Code] 
function GetIDLPath(dummy: string): string; 
begin 
    RegQueryStringValue(HKEY_LOCAL_MACHINE, 'SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\idlrt.exe', '', Result); 
    if Result = '' then 
    Result := 'idlrt.exe'; 
end; 

但目標位置最終被：

C:\clas\bin\BATCH_CLAS_MAIN.sav 

它應該是：

"C:\Program Files\Exelis\IDL82\bin\bin.x86\idlrt.exe" -vm C:/clas/bin/BATCH_CLAS_MAIN.sav 

我在註冊表檢查idlrt.exe位置和我我正在提供正確的路徑，

有誰知道什麼是錯的？

Answer 1

至少我可以看到Parameters參數值有問題。如果您傳遞可展開的"{app}\bin\BATCH_CLAS_MAIN.sav"常數，則無法通過-vm選項跟隨{app}/bin/BATCH_CLAS_MAIN.sav路徑以正斜槓得到預期結果。這可能會更好一點：

[Setup] 
AppName=My Program 
AppVersion=1.5 
DefaultDirName=My Program 

[Icons] 
; because of use of the "useapppaths" flag, there's no need to have the 
; GetIDLPath function anymore; that flag do its work for you 
Name: "{group}\clas"; Filename: "idlrt.exe"; Parameters: "{code:GetIDLParams}"; IconFilename: "{app}\clas_icon.ico"; Flags: useapppaths 

[Code] 
function GetIDLParams(Value: string): string; 
begin 
    // prepare the -vm option followed by a quoted application path to a file 
    Result := '-vm ' + AddQuotes(ExpandConstant('{app}\bin\BATCH_CLAS_MAIN.sav')); 
    // and replace backslashes to forward slashes 
    StringChangeEx(Result, '\', '/', False); 
end;