MS-DOS批處理腳本：賦值操作

Question

我指的是下面的威脅Batch files: How to read a file?。用於從文本文件中逐行檢索。我正在使用下面的腳本：

@echo off 
SETLOCAL DisableDelayedExpansion 
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ paths.txt"`) do (
    set "var=%%a" 
    SETLOCAL EnableDelayedExpansion 
    set "var=!var:*:=!" 
    echo !var! 
    ENDLOCAL 
) 

代碼工作正常！ !var!中的值不能分配給任何變量。 :(我有結構，請人幫忙看一行行，我要分配給一些變量，要操縱變量請幫忙解決這個情況

更新：。

@ECHO off 

CLS 

SET PROJ_DIR=D:\workspace\proj 
SET PROMO_DIR=D:\TEST 
SET SOURCE_CODE=\Source Code 

SETLOCAL DisableDelayedExpansion 
for /f %%a in (paths.txt) do (
    SET "var=%%a" 
    SETLOCAL EnableDelayedExpansion 
    set "var=!var:*:=!" 
    set FILE_PATH=!var://www.domain.com/path/dir=! 
    SET FILE_PATH=!FILE_PATH:/=\! 
    SET PROMO_FILE_PATH=!PROMO_DIR!!SOURCE_CODE!!FILE_PATH! 
    FOR %%i IN ("!PROMO_FILE_PATH!") DO SET FOLDER_PATH=%%~dpi 
    FOR %%i IN ("!PROMO_FILE_PATH!") DO SET FILE_NAME=%%~nxi 
    IF EXIST "!FOLDER_PATH!" GOTO F3 
     MKDIR "!FOLDER_PATH!" 
    :F3 
    IF NOT EXIST "!PROJ_DIR!!FILE_PATH!" GOTO F4 
     COPY "!PROJ_DIR!!FILE_PATH!" "!FOLDER_PATH!" 
    :F4 
     ECHO Cannot find the file under "!PROJ_DIR!!FILE_PATH!" 

    ENDLOCAL 
) 

SET CLOSE_CONFIRM= 
SET /P CLOSE_CONFIRM=Press any key to close the window...%=% 

paths.txt

//www.domain.com/path/dir/dir1/dir2/file1.txt 
//www.domain.com/path/dir/dir1/dir2/file2.txt 
//www.domain.com/path/dir/dir1/dir2/file3.txt 
//www.domain.com/path/dir/dir1/dir2/file4.txt 
//www.domain.com/path/dir/dir1/dir3/file1.txt 

命令輸出

 1 file(s) copied. 
Cannot find the file under "D:\workspace\proj\dir1\dir2\file1.txt" 
     1 file(s) copied. 
Cannot find the file under "D:\workspace\proj\dir1\dir2\file2.txt" 
Press any key to close the window... 

感謝..

Answer 1

的關鍵是延遲的擴張，!不%擴大括號裏面的變量始終。

改變樣品X與Y

@echo off 
SETLOCAL DisableDelayedExpansion 
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ paths.txt"`) do (
    set "var=%%a" 
    SETLOCAL EnableDelayedExpansion 
    set "var=!var:*:=!" 
    set "myVar=!var!" 
    set "myVar=!myVar:X=Y!" 
    echo X replaced with Y =!myVar! 
    ENDLOCAL 
) 

在更新後的版本轉到：標籤停止for循環立刻

更好它改寫爲IF塊

IF NOT EXIST "!FOLDER_PATH!" (
    MKDIR "!FOLDER_PATH!" 
) 
IF EXIST "!PROJ_DIR!!FILE_PATH!" (
    COPY "!PROJ_DIR!!FILE_PATH!" "!FOLDER_PATH!" 
) ELSE 
(
    ECHO Cannot find the file under "!PROJ_DIR!!FILE_PATH!" 
) 

Answer 2

如果你想讀的每一行，並對其進行操作：

SETLOCAL EnableDelayedExpansion 
FOR /F "tokens=*" %%a IN (paths.txt) DO (
set var=%%a 
ECHO %var% 
PAUSE 
) 
ENDLOCAL 

如果你正試圖從一個文件中搜索字符串並操縱它：

SETLOCAL EnableDelayedExpansion 
FOR /F "tokens=* usebackq" %%a IN (`FIND /I 'string to search for' "C:\folder\paths.txt"`) DO (
set var=%%a 
ECHO %var% 
PAUSE 
) 
ENDLOCAL 

如果您嘗試搜索字符串並操縱字符串中的每個單詞：

SETLOCAL EnableDelayedExpansion 
FOR /F "usebackq tokens=1-999 delims= " %%a IN (`FIND /I 'string to search for' "C:\folder\paths.txt"`) DO (
REM %%a = first word %%b = second word etc. through the alphabet 
set var1=%%a%%b%%c 
set var2=%%d 
ser var3=%%e 
ECHO %var1% %var2% %var3% 
PAUSE 
) 
ENDLOCAL 

Answer 3

這個工作對我來說：

@echo off 
SETLOCAL EnableDelayedExpansion 

FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ paths.txt"`) do (
set var=%%a 
set var=!var:*:=! 
echo !var! 
) 
ENDLOCAL 

Answer 4

這裏的其他答案涵蓋了這段代碼中延遲擴展的棘手問題。我想補充一點，通過將括號滾動到子例程中，您通常可以避免大多數延遲擴展問題。

FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ paths.txt"`) do call :HandlePath %%a 
goto :eof 

================ 
:HandlePath 
set "var=%*" 
set "var=%var:*:=%" 
echo %var% 
goto :eof 

我覺得這段代碼更容易維護，因爲每一行都被解析執行，正如你所期望的那樣。