將一個表中的一系列值應用到另一個表中的一系列行中

Question

假設我有表@A，其中有一系列行，其中有一行包含NULL值，對於這些行，我有表@B（可能更少，或者更多）行的值，如何將@B的值應用於@A的行以填充NULL，而不更改@B？ （我沒有使用遊標，我的意思是：遊標相當平凡）@A和@B都是內存中的（表變量），只有少量的行，所以我們不必擔心大數據集。

例如，如果我有：

DECLARE @A TABLE 
(
     x INT, 
     y NVARCHAR(20) 
) 
INSERT INTO @A (y) VALUES ('aaa'), ('bbb'), ('ccc') 

DECLARE @B TABLE 
(
     x INT 
) 
INSERT INTO @B (X) values (1), (2) 

現在我有@A：

 
x   y 
----------- ----------- 
NULL  aaa 
NULL  bbb 
NULL  ccc 

和@B：

 
x 
----------- 
1 
2 

...我想更新@A基於所以它有：

 
x   y 
----------- ----------- 
1   aaa 
2   bbb 
NULL  ccc 

...理想地以該順序（例如，在@B最低值變爲x用於@A最低y，那麼下一個，等等）。

我覺得有一個相當簡單的方法來做到這一點，但我沒有收到有...

Answer 1

此查詢將有助於獲得預期的結果。

DECLARE @A TABLE 
(
     x INT, 
     y VARCHAR(10) 
) 
INSERT INTO @A (y) SELECT ('aaa') UNION SELECT('bbb') UNION SELECT('ccc') 

DECLARE @B TABLE 
(
     x INT 
) 
INSERT INTO @B (X) SELECT (1) UNION SELECT (2) 


UPDATE A SET x = B.x FROm 
    (SELECT *, ROW_NUMBER() OVER (ORDER BY y) AS RoW1 FROM @A) AS A 
    INNER JOIN 
    (SELECT *, ROW_NUMBER() OVER (ORDER BY x) AS RoW1 FROM @B) AS B 
    ON A.RoW1 = B.RoW1 

SELECT * FROm @A 

Answer 2

這個工作

DECLARE @A TABLE 
(
     x INT, 
     y NVARCHAR(20) 
) 
INSERT INTO @A (y) VALUES ('aaa'), ('bbb'), ('ccc') 

DECLARE @B TABLE 
(
     x INT 
) 
INSERT INTO @B (X) values (1), (2) 

Select * into #X from @B 
DECLARE @Val1 INT 
WHILE 0 < (Select COUNT(*) from #X) 
    BEGIN 
    SET ROWCOUNT 1 
    Select @Val1 = MIN(x) from #X 
    UPDATE @A set x = @Val1 where y = (Select MIN(y) from @A where x is null) 
    Delete #X where x = @Val1 
    if 0 = (Select Count(*) from @A where x is null) 
    break 

    END 
SET ROWCOUNT 0 
Select * from @A 

它可能不是優雅，但它的工作原理