如何篩選和使用sxlt

Question

我有這樣的XML文件中刪除一些節點在一個XML文件：

<A> 
<B> 
    <elt>Add</elt> 
    ...there are some element here 
    <bId>2</bId> 
</B> 
<B> 
    <elt>Add</elt> 
    ...there are some element here 
    <bId>2</bId> 
</B> 
<B> 
    <elt>Add</elt> 
    ...there are some element here 
    <bId>2</bId> 
</B> 
<B> 
    <elt>can</elt> 
    ...there are some element here 
    <bId>3</bId> 
</B> 
<B> 
    <elt>can</elt> 
    ...there are some element here 
    <bId>3</bId> 
</B> 

我要檢查每個投標元素的值。如果這個值與之前或之後的元素相同，那麼我會將其他元素的區塊放入另一個區塊，例外元素bId這將在轉換後被拒絕。要通過你讓我的問題的理解，這裏是預期的輸出：

<CA> 
    <cplx> 
    <spRule> 
      <elt>Add</elt> 
      ... 
    </spRule> 
    <spRule> 
      <elt>Add</elt> 
      ... 
    </spRule> 
    <spRule> 
      <elt>Add</elt> 
      ... 
    </spRule> 
    </cplx> 
    <cplx> 
    <spRule> 
      <elt>can</elt> 
      ... 
    </spRule> 
    <spRule> 
      <elt>can</elt> 
      ... 
    </spRule> 
    </cplx> 
</CA> 

即使當在XML文件中的元素不被的的值排序投標，我想也得到了相同的預期輸出。 我嘗試使用這個XSL代碼：

<xsl:for-each select="bId" 
    <CA> 
    <cplx> 
    <xsl:choose> 
     <xsl:when test="node()[preceding::bId]"> 
     <xsl:copy> 
      <xsl:copy-of select="@*"/> 
      <xsl:apply-templates/> 
     </xsl:copy> 
     </xsl:when> 
    </cplx> 
    </CA> 
</xsl:for-each> 

，但它不走。請有人幫助我嗎？ 感謝

Answer 1

假設你的第一次描述具有相同bId值組相鄰的元素是你想要什麼的XSLT 1.0方法如下：

<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:strip-space elements="*"/> 
    <xsl:output indent="yes"/> 

    <xsl:key name="k1" 
    match="B[bId = preceding-sibling::B[1]/bId]" 
    use="generate-id(preceding-sibling::B[not(bId = preceding-sibling::B[1]/bId)][1])"/> 

    <xsl:template match="A"> 
    <CA> 
     <xsl:apply-templates select="B[not(preceding-sibling::B[1]) or not(bId = preceding-sibling::B[1]/bId)]"/> 
    </CA> 
    </xsl:template> 

    <xsl:template match="B"> 
    <cplx> 
     <xsl:apply-templates select=". | key('k1', generate-id())" mode="sp"/> 
    </cplx> 
    </xsl:template> 

    <xsl:template match="B" mode="sp"> 
    <spRule> 
     <xsl:copy-of select="node()[not(self::bId)]"/> 
    </spRule> 
    </xsl:template> 

</xsl:stylesheet> 

如果你只是想將所有B元素具有相同bId值，則使用

<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:strip-space elements="*"/> 
    <xsl:output indent="yes"/> 

    <xsl:key name="k1" 
    match="B" 
    use="bId"/> 

    <xsl:template match="A"> 
    <CA> 
     <xsl:apply-templates select="B[generate-id() = generate-id(key('k1', bId)[1])]"/> 
    </CA> 
    </xsl:template> 

    <xsl:template match="B"> 
    <cplx> 
     <xsl:apply-templates select="key('k1', bId)" mode="sp"/> 
    </cplx> 
    </xsl:template> 

    <xsl:template match="B" mode="sp"> 
    <spRule> 
     <xsl:copy-of select="node()[not(self::bId)]"/> 
    </spRule> 
    </xsl:template> 

</xsl:stylesheet>