如何在使用Gradle的AppEngine項目中使用Kotlin

Question

就像標題所說的那樣，在開發AppEngine項目時如何使用Kotlin？我將使用IntelliJ/Android Studio和Gradle作爲我的構建工具。

Answer 1

由於AppEngine執行已編譯的.class文件，因此它並不關心JVM語言生成的這些文件。這意味着我們可以使用Kotlin。

一種方法是使用Gradle和Gradle App Engine plugin。用build.gradle創建一個類似this的項目。然後添加Kotlin依賴關係並應用插件。最後一個build文件看起來是這樣的：

buildscript { 
    ext.kotlin_version = '1.0.6' //replace with latest Kotlin version 
    repositories { 
     mavenCentral() 
    } 
    dependencies { 
     classpath 'com.google.appengine:gradle-appengine-plugin:1.9.32' //Replace with latest GAE plugin version 
     classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version" 
    } 
} 

repositories { 
    mavenCentral(); 
} 

apply plugin: 'java' 
apply plugin: 'kotlin' 
apply plugin: 'war' 
apply plugin: 'appengine' 

sourceCompatibility = JavaVersion.VERSION_1_7 
targetCompatibility = JavaVersion.VERSION_1_7 

dependencies { 
    appengineSdk 'com.google.appengine:appengine-java-sdk:1.9.32' //Replace with latest GAE SDK version 
    compile 'javax.servlet:servlet-api:2.5' 
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version" 
} 

appengine { 
    downloadSdk = true 
    appcfg { 
     oauth2 = true 
    } 
} 

由於M11，你不需要有科特林文件的一個單獨的目錄，以便您可以將您的文件.kt只需添加到src/main/java。